63456_it-IT

liliconcom

Eliminazione di dati che non rientrano nell'intervallo di date richiesto

Ho due date salvate in un file di testo nel formato mm / gg / aaaa. Devo analizzare i dati che rientrano in questo intervallo di date e cancellare tutti gli altri dati.

Come posso fare questo?

Ri: Eliminazione di dati che non rientrano nell'intervallo di date richiesto

Ecco due esempi di come è possibile eseguire un'analisi basata sulle date lette in un file di testo

Names Default To Here( 1 );

// Create a sample data table
dt = New Table( "Example",
 Add Rows( 7 ),
 New Column( "ACTUAL_SHORT_DATE",
  Numeric,
  "Continuous",
  Format( "m/d/y", 12 ),
  Input Format( "m/d/y" ),
  Set Values(
   [3612470400, 3614025600, 3618777600, 3614457600, 3613420800,
   3578947200, 3613939200]
  ),
  Set Display Width( 154 )
 ),
 New Column( "Sample Data",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values(
   [0.865467654397147, 0.551025322305757, -0.780534757628151,
   0.590164622893679, -0.084595197133406, 0.93192690045854,
   -0.652714499840696]
  )
 )
);

// Read the data from the text file
textValue = Load Text File( "C:\Temp\DateRange.txt" );

// Parse out the start and end dates
startDate = Informat( Word( 1, textValue, " " ) );
endDate = Informat( Word( 2, textValue, " " ) );

// Select the data that falls within the start
// and end dates
dt << select where(
 :ACTUAL_SHORT_DATE > startDate & :ACTUAL_SHORT_DATE < endDate
);

// Subset
dtSub = dt << Subset(
 Selected Rows( 0 ),
 Rows( [2, 4, 5, 7] ),
 Selected columns only( 0 )
);
 
// Analyze the data
dtSub << Bivariate( Y( :Sample Data ), X( :ACTUAL_SHORT_DATE ) );

Names Default To Here( 1 );

// Create a sample data table
dt = New Table( "Example",
 Add Rows( 7 ),
 New Column( "ACTUAL_SHORT_DATE",
  Numeric,
  "Continuous",
  Format( "m/d/y", 12 ),
  Input Format( "m/d/y" ),
  Set Values(
   [3612470400, 3614025600, 3618777600, 3614457600, 3613420800,
   3578947200, 3613939200]
  ),
  Set Display Width( 154 )
 ),
 New Column( "Sample Data",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values(
   [0.865467654397147, 0.551025322305757, -0.780534757628151,
   0.590164622893679, -0.084595197133406, 0.93192690045854,
   -0.652714499840696]
  )
 )
);

// Read the data from the text file
textValue = Load Text File( "C:\Temp\DateRange.txt" );

// Parse out the start and end dates
startDate = Informat( Word( 1, textValue, " " ) );
endDate = Informat( Word( 2, textValue, " " ) );

// Select the data that falls outside the start
// and end dates
dt << select where(
 :ACTUAL_SHORT_DATE < startDate | :ACTUAL_SHORT_DATE > endDate
);

// Hide and exclude the selected rows
dt << Hide and Exclude;

dt << clear select;
 
// Analyze the data
dt << Bivariate( Y( :Sample Data ), X( :ACTUAL_SHORT_DATE ) );

Ri: Eliminazione di dati che non rientrano nell'intervallo di date richiesto

Grazie per la risposta. Inserimento di un file di testo di esempio. Ho tutti i dati nella tabella jmp che contiene anche una colonna di data JMP valida.

Ri: Eliminazione di dati che non rientrano nell'intervallo di date richiesto

1.  Come si presenta la struttura del file di testo?

2. I dati devono essere analizzati già in una tabella di dati JMP?

3. C'è una colonna della data JMP valida nei dati da analizzare?

 

Fondamentalmente, quello che dovresti fare è leggere le date dal file di testo.  Quindi trovare tutte le righe nella tabella di analisi che soddisfano tale requisito e quindi suddividere tali righe in una nuova tabella di dati.  Infine, eseguirai la tua analisi sulla tabella dei dati subsetted.

 

Se potessi fornire maggiori dettagli sulla struttura del file di testo e sul file / tabella dati, potrei trovare una soluzione per te.