75111_de-DE

liliconcom

Wie speichere ich eine Datentabelle ohne Spaltennamen in TXT?

Hallo alle zusammen:

Wie speichere ich eine Datentabelle ohne Spaltennamen in TXT? Vielen Dank!

Betreff: Wie speichere ich eine Datentabelle ohne Spaltennamen in TXT?

Hallo,

Da ich bestimmte Zeichenfolgenketten in separaten Zeilen in einer Textdatei speichern muss, habe ich die obige Lösung von txnelson eins zu eins ausprobiert, sie gibt jedoch eine Datei zurück, in der jedoch Zeichenfolgenketten in einer Zeile gespeichert sind. Es scheint, dass das Zeilenumbruchzeichen in meinem Fall nicht den gewünschten Effekt bringt. Was vermisse ich?

Mit freundlichen Grüßen

 

BEARBEITEN:

ok, statt "\!n" Ich schrieb "\!r\!n" und dann wie gewünscht gearbeitet.

Betreff: Wie speichere ich eine Datentabelle ohne Spaltennamen in TXT?Es ist ein Meisterwerk. Danke sehr!Betreff: Wie speichere ich eine Datentabelle ohne Spaltennamen in TXT?

Alternativ können Sie Ihre Exporteinstellungen ändern, die Datei speichern und die Standardeinstellungen wiederherstellen.

Das folgende Skript enthält die Schritte. Es ist dokumentiert im JSL Companion, 2nd Ed. script 2_Extra_SaveText.jsl

Names Default to Here(1);

//Get a copy of the user's settings
_xx = Get Preference( Export settings);

//set the text export preferences you want
Preference(
 Export Settings(
  End Of Line( CRLF ),
  End Of Field( Comma, CSV( 1 ) ),
  Export Table Headers( 0 ),
  Quote all column names( 0 ),
  Quote all character values( 0 ),
  Quote all numeric values( 0 )
 )
);
//you can look at preferences now an they will be changed.

dt = Open("$Sample_data/Big Class.jmp");
dt << Save("c:/temp/bclass.txt");

//reset the user's preferences
_xx;

Betreff: Wie speichere ich eine Datentabelle ohne Spaltennamen in TXT?

Auch dafür brauchte ich eine Lösung. Vielen Dank für die Lösung txnelson.

Betreff: Wie speichere ich eine Datentabelle ohne Spaltennamen in TXT?Danke Jim!
Es wird einfach so durchlaufen. Dasselbe gilt für VBA.Betreff: Wie speichere ich eine Datentabelle ohne Spaltennamen in TXT?

Hier ist ein einfaches Skript, das das tut, was Sie wollen

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

// Loop across all rows
For( i = 1, i <= N Rows( dt ), i++,
 // Copy all columns for the given row into a list
 rowVals = dt[i, 0];
 
 // Initialize a string variable
 theString = "";
 
 // Loop across all values in the row list, and place them into the string variable
 For( k = 1, k <= N Items( rowVals ), k++,
  If( k > 1,
   // After the first value, add a comma between the values
   theString = theString || ","
  );
  theString = theString || char(rowVals[k]);
 );
 
 // Add a new line character at the end of the line
 theString=theString||"\!n";
 
 // Write the row's values to the output txt file
 If(i==1,
  save text file("$TEMP/myfile.txt",theString,mode("replace")),
  save text file("$TEMP/myfile.txt",theString,mode("append"))
 )
);