JMPで一連の座標を囲む境界ボックスを生成することは可能ですか？すべて、
一連の座標がある場合は、指定された半径内で境界ボックスの座標を生成できる地理空間関数があります。
例えば
緯度= 47.80
経度= -122.00
半径10マイル以内のこれらの座標の周囲に境界ボックスを生成したいと思います。JMPにはこのための組み込み機能がありますか？
私は「R」を使ってこれを達成することができましたが、可能であればJMPでこれを行うのを好む場合を除いて。また、関数の関数ドキュメントは分数を受け付け、必ずしも距離を受け付けません - 分数が何を象徴しているのか明確ではありません。あいまいさを排除するために、可能であればJMPでそれをすることを好みます。
Lat <- 47.80
Lon <- -122.00
Rad <- 0.05
BBox <- ggmap::make_bbox(lon = Lon,lat = Lat,f = Rad)
再：それはJMPの座標のセットの周りにバウンディングボックスを生成することは可能ですか？この郵便受けあなたを指すでしょうこのサイトそれは地球上の点と他の有用な公式の間の距離を計算するためのhaversine公式を説明します。セクションの式を使いました始点からの距離と方位が与えられた目的地点中心位置の周囲に点の円を作成します。私の投稿では、私はあらゆる方向に90度離れた距離を使いました。10マイルは学位のほんの一部になります。（少なくともそれが私がしたと思う方法です。ちょっと運が良ければ、JSLにいくつかのコメントがあります。）
Projected circle of sunlight日光の射影円
再：それはJMPの座標のセットの周りにバウンディングボックスを生成することは可能ですか？バウンディングボックスの使用目的がわからない場合でも、JSLによるGraph Builderマップの「ズーム」（メートル法からの素早い適応）を制御するために、以下のようなものを使用しました。
Names default to here(1);
// Desired map central position and distance to view boundary
Lat = 40.782222; //Latitude
Lon = -73.965278; //Longitude
Rad = 7; // miles
// Calculate bounding box coordinates with geodetic approximation (WGS84)
a = 6378137; // Radius of earth at equator (m)
e2 = 0.00669437999014; // eccentricity squared
m = 1609.344; // 1 mile in meters
r = Pi() / 180; // convert to radians
//Distance of 1° latitude (miles)
d1 = r * a * (1 - e2) / (1 - e2 * Sin(Lat * r) ^ 2) ^ (3 / 2) / m;
//Distance of 1° longitude (miles)
d2 = r * a * Cos(Lat * r) / Sqrt(1 - e2 * Sin(Lat * r) ^ 2) / m;
//Bounding box coordinates
{minLat, maxLat} = {Lat - Rad / d1, Lat + Rad / d1};
{minLon, maxLon} = {Lon - Rad / d2, Lon + Rad / d2};
//––––––––––––––––––––––––––––––––––––––––––––––––––
//Example map
dt = Open("$SAMPLE_DATA/SAT.jmp");
gb = dt << Graph Builder(Variables(X(:Longitude), Y(:Latitude)), Elements(Points(X, Y)));
Report(gb)[FrameBox(1)] << Background Map(Images("Street Map Service")); Wait(1);
//Set bounding box (Manhattan, ~13 miles long)
Report(gb)[ScaleBox(2)] << {Min(minLat), Max(maxLat)};
Report(gb)[ScaleBox(1)] << {Min(minLon), Max(maxLon)};
