是否可以在JMP中圍繞一組坐標生成邊界框？所有，
如果我有一組坐標，是否有一個地理空間函數可以生成指定半徑內的邊界框的坐標。
例如
緯度= 47.80
經度= -122.00
我想在10英里範圍內圍繞這些坐標生成一個邊界框。JMP是否有任何內置功能？
我能夠使用“R”來實現這一點，除非我願意盡可能在JMP中這樣做。此外，函數的函數文檔接受一個分數而不一定是距離 - 不清楚分數的符號。為了消除歧義，我更願意在JMP中盡可能地做到這一點。
Lat <- 47.80
Lon <- -122.00
Rad <- 0.05
BBox <- ggmap::make_bbox(lon = Lon,lat = Lat,f = Rad)
Re：是否可以在JMP中圍繞一組坐標生成邊界框？這個帖子會指出你的這個網站它描述了用於計算地球上的點之間的距離和其他有用公式的半正式公式。我在本節中使用了公式給定距離的目的地點和從起點開始的方位在中心位置周圍創建一個圓點。在我的帖子中，我使用了距離各個方向90度的距離。10英里將是一個程度的一小部分。（至少那是我認為我這樣做的方式。運氣不錯，JSL中有一些評論。）
Projected circle of sunlight預計的陽光圈
Re：是否可以在JMP中圍繞一組坐標生成邊界框？不確定你打算使用邊界框，但是我使用了類似下面的內容來控制JSL對Graph Builder地圖的“縮放”（從公制系統中快速適應）。
Names default to here(1);
// Desired map central position and distance to view boundary
Lat = 40.782222; //Latitude
Lon = -73.965278; //Longitude
Rad = 7; // miles
// Calculate bounding box coordinates with geodetic approximation (WGS84)
a = 6378137; // Radius of earth at equator (m)
e2 = 0.00669437999014; // eccentricity squared
m = 1609.344; // 1 mile in meters
r = Pi() / 180; // convert to radians
//Distance of 1° latitude (miles)
d1 = r * a * (1 - e2) / (1 - e2 * Sin(Lat * r) ^ 2) ^ (3 / 2) / m;
//Distance of 1° longitude (miles)
d2 = r * a * Cos(Lat * r) / Sqrt(1 - e2 * Sin(Lat * r) ^ 2) / m;
//Bounding box coordinates
{minLat, maxLat} = {Lat - Rad / d1, Lat + Rad / d1};
{minLon, maxLon} = {Lon - Rad / d2, Lon + Rad / d2};
//––––––––––––––––––––––––––––––––––––––––––––––––––
//Example map
dt = Open("$SAMPLE_DATA/SAT.jmp");
gb = dt << Graph Builder(Variables(X(:Longitude), Y(:Latitude)), Elements(Points(X, Y)));
Report(gb)[FrameBox(1)] << Background Map(Images("Street Map Service")); Wait(1);
//Set bounding box (Manhattan, ~13 miles long)
Report(gb)[ScaleBox(2)] << {Min(minLat), Max(maxLat)};
Report(gb)[ScaleBox(1)] << {Min(minLon), Max(maxLon)};
