Añadiendo barras de error en JMP<meta http-equiv="Content-Type" content="text/html; charset=UTF-8" />Hola chicos, tengo un problema simple que no he podido resolver. Tengo un conjunto de datos que me gustaría trazar en un diagrama de dispersión de estilo Fit Y by X contra otro conjunto de datos. Para cada punto de datos, conozco la desviación estándar y me gustaría agregar estas desviaciones estándar como barras de error a la gráfica, ¿hay alguna forma de hacer esto?
Parece que JMP solo hace esto normalmente si ha calculado la desviación estándar, no quiero hacerlo porque ya conozco la desviación estándar para todos y cada uno de los puntos de datos.
Gracias por cualquier ayuda
Agregar barras de error en JMPEs posible utilizar Graph Builder para mostrar barras de error sin apilar los datos. Es decir, tiene 3 columnas separadas: punto central, límite superior y límite inferior. Usando los datos anteriores, arrastra la variable X (edad) al eje X. Luego resalte superior e inferior y arrástrelos al eje Y. Haga clic derecho en el centro del gráfico, haga clic en Puntos > Cambiar a > Barra. Luego haga clic derecho en el gráfico, haga clic en Barra > Estilo de barra > Intervalo. Ahora arrastre la columna Media (altura) justo a la derecha del eje Y. Luego agregue líneas de conexión y elimine las líneas de conexión para la parte superior e inferior.
Aquí hay un script JSL que lo hace, junto con algo de formato:
// Make an example table
dt = Open( "$ENGLISH_SAMPLE_DATA/Big Class.jmp" );
dtsum = dt << Summary( Group( :age ), Mean( :height ), Std Err( :height ) );
// Add columns with Mean ± SE
dtsum << New Column( "lower", numeric,
values(
(:Name( "Mean(height)" ) << get as matrix) –
(:Name( "Std Err(height)" ) << get as matrix)
)
);
dtsum << New Column( "upper",
numeric,
values(
(:Name( "Mean(height)" ) << get as matrix) +
(:Name( "Std Err(height)" ) << get as matrix)
)
);
Graph Builder(
Show Control Panel( 0 ),
Variables(
X( :age ),
Y( :lower ),
Y( :upper, Position( 1 ) ),
Y( :Name( "Mean(height)" ), Position( 1 ) )
),
Elements(
Bar(
X,
Y( 1 ),
Y( 2 ),
Y( 3 ),
Legend( 2 ),
Bar Style( "Interval" ),
Summary Statistic( "Mean" )
),
Line( X, Y( 3 ), Legend( 4 ), Row order( 0 ), Summary Statistic( "Mean" ) )
),
SendToReport(
Dispatch(
{},
"400",
ScaleBox,
{Legend Model(
2,
Properties( 0, {Line Color( 0 )} ),
Properties( 1, {Line Color( 0 ), Marker( "FilledCircle" )} )
)}
),
Dispatch( {}, "Graph Builder", FrameBox, {Marker Size( 3 )} )
)
);
Re: Agregar barras de error en JMPEsto fue muy útil para mí, estoy tratando de escribir un script JSL para poder trazar barras de error de desviación estándar en un gráfico de control, ya que cada punto de datos en el gráfico de control es el promedio de x puntos individuales. ¿Existe alguna forma de que el script JSL utilizado para Graph Builder se pueda utilizar en el script Run Chart, XBar, IR, UWMA o PreSummarize Control Chart?
Re: Agregar barras de error en JMPExiste una opción más sencilla, incluso sin el problema de la fluctuación cuando se utiliza una variable de superposición adicional. Primero, cree una columna para el valor inferior y el superior de cada uno (como se describe arriba). Luego, apile los datos (punto central, valor superior, valor inferior). Abra el generador de gráficos y agregue los datos apilados al eje y. Luego, elija la estadística de resumen "media" y las barras de error "rango". Eso es todo. ¡Incluso sin el problema de la fluctuación! Buena suerte 
Agregar barras de error en JMPEs posible pero no he encontrado una forma sencilla de hacerlo. Primero necesitas calcular la media-SE y la media+SE. Entonces obtendrás el mejor resultado si primero apilas las columnas. Pruebe el siguiente script. Ilustra algunas formas de hacerlo en JMP 9.
// Make an example table
dt = Open( "$ENGLISH_SAMPLE_DATA/Big Class.jmp" );
dtsum = dt << Summary( Group( :age ), Mean( :height ), Std Err( :height ) );
// Add columns with Mean ± SE
dtsum << New Column( "lower",
numeric,
values(
(:Name( "Mean(height)" ) << get as matrix) - (:Name( "Std Err(height)" ) << get as matrix)
)
);
dtsum << New Column( "upper",
numeric,
values(
(:Name( "Mean(height)" ) << get as matrix) + (:Name( "Std Err(height)" ) << getasmatrix)
)
);
// Stack columns
dtstacked = dtsum << Stack(
columns( :Name( "Mean(height)" ), :lower, :upper ),
Source Label Column( "Label" ),
Stacked Data Column( "Data" ),
Name( "Non-stacked columns" )(Keep( :age ))
);
// Three ways to make a graph with mean and error bars based known SE
// 1. Overlay plot with range plot. Ugly graph and markers are visible for ± SE
dtsum << Overlay Plot( X( :age ), Y( :Name( "Mean(height)" ), :lower, :upper ), Range Plot( 1 ) );
// 2. Graph builder. Nicer graph but table must be stacked first.
dtstacked << Graph Builder(
Show Control Panel( 0 ),
Variables( X( :age ), Y( :Data ) ),
Elements(
Points(
X,
Y,
Legend( 0 ),
Jitter( 0 ),
Summary Statistic( "Mean" ),
Error Bars( "Range" ),
)
)
);
// 3. Chart platform. Similar to graph in 2.
dtstacked << Chart(
X( :age ),
Y( Mean( :Data ) ),
Add Error Bars to Mean( Range ),
Overlay Axis << {{Min( 52.5 ), Max( 72.5 ), Inc( 5 ), Minor Ticks( 1 )}},
Y[1] << Point Chart( 1 )
);
Re: Agregar barras de error en JMPPor ejemplo
Re: Agregar barras de error en JMPHay una función de 'Intervalo' que le permite agregar las barras de error (es decir, con una columna que contiene las desviaciones estándar para cada fila/muestra):
Re: Agregar barras de error en JMPHay un complemento de Ian Cox que podría ser lo que estás buscando.
Complemento JMP que grafica la incertidumbre en los valores X e Y
Re: Agregar barras de error en JMPEsto es realmente útil, pero ¿cómo se eliminan las líneas de conexión entre las partes superior e inferior (además de mediante un script)?
Gracias,
Phil
Re: Agregar barras de error en JMPHaz clic derecho en el gráfico y selecciona Línea > Y > superior (o como hayas llamado la columna del límite superior). Repite el proceso para el límite inferior.
Re: Agregar barras de error en JMPGenial. No me había dado cuenta de que fuera tan sencillo.
Gracias.
Re: Agregar barras de error en JMPGracias por la respuesta. Cualquiera de los tres métodos funciona bien para incluir barras de error en el eje Y. ¿Sabes cómo puedo incluir barras de error tanto en el eje X como en el eje Y en el mismo diagrama de dispersión?
