49520_es-ES

liliconcom

Guardar la trama bivariada a JPEG

Hola, pude conseguir la trama bivariada. Pero no puedo guardar la trama como una imagen porque tengo un error en mi guardado.

 

Cualquier ayuda sería genial. Gracias.

 

 

 

<BR />Open("C:\jmp_data\NamesData.jmp", window bounds(600, 50, 500, 400), window state(maximized)); 

window_DATA = New Window("NAMES SHOW", Bivariate(Y(:Name("AGES")), X(:Name("GENDER")), Fit Line({Line Color({100, 50, 50})}))) << Maximize Display << Set Window Icon("FitYByX"); <BR />
window_DATA << save picture( "C:\jmp_data\NamesAge.JPG", JPEG );

 

Re: Guardar trama bivariada a JPEG

Aparentemente, al menos en 13.2.1, el mensaje Guardar imagen funciona pero no está documentado. Al menos para mí, solo agregar paréntesis al código original funciona.

Re: Guardar trama bivariada a JPEG

El objeto de ventana no tiene un mensaje de Guardar imagen disponible para él.  Consulte el índice de secuencias de comandos para ver los mensajes que se pueden pasar al objeto de la ventana.  Lo que debe hacer es guardar un objeto dentro de la ventana que admite el mensaje Guardar imagen. Aquí hay una posible solución.

Names Default to Here( 1 );
Open(
 "C:\jmp_data\NamesData.jmp",
 window bounds( 600, 50, 500, 400 ),
 window state( maximized )
); 

window_DATA = New Window( "NAMES SHOW",
 Biv = Bivariate(
  Y( :Name( "AGES" ) ),
  X( :Name( "GENDER" ) ),
  Fit Line( {Line Color( {100, 50, 50} )} )
 )
) << Maximize Display << Set Window Icon( "FitYByX" );
report( Biv ) << save picture( "C:\jmp_data\NamesAge.JPG", JPEG );

Re: Guardar trama bivariada a JPEG

Supongo que el error que recibes se relaciona con la necesidad de un objeto programable.  En este momento, envía un mensaje a la ventana y guarda el resultado del mensaje enviado en window_DATA.  En su lugar, desea guardar una referencia a la ventana en sí y luego enviarle un mensaje.  Dos opciones son:

1. Hágalo todo en una 'línea', similar a su código ahora, pero use el orden de las operaciones para asegurarse de que la variable esté definida antes de enviar un mensaje a la ventana, o
2. Haga esto en dos líneas.

Recomiendo este último ya que es más legible.

Names default to here( 1 );

dt = Open("$Sample_data/iris.jmp"); 

//All at once
( window_DATA_1 = New Window( "NAMES SHOW", 
 Bivariate( 
  Y( :Name( "Sepal length" ) ), 
  X( :Name( "Petal length" ) ), 
  Fit Line( {Line Color( {100, 50, 50} )} )
 ) 
) ) << Maximize Display << Set Window Icon( "FitYByX" );

window_DATA_1 << save picture( "$Desktop\Picture_1.JPG", JPEG );

//In two steps
window_DATA_2 = New Window( "NAMES SHOW", 
 Bivariate( 
  Y( :Name( "Sepal length" ) ), 
  X( :Name( "Petal length" ) ), 
  Fit Line( {Line Color( {100, 50, 50} )} )
 ) 
);

window_DATA_2 << Maximize Display << Set Window Icon( "FitYByX" );

window_DATA_2 << save picture( "$Desktop\Picture_2.JPG", JPEG );