49520_de-DE

liliconcom

Speichern Sie das bivariate Diagramm in JPEG

Hallo, ich konnte den Bivariate-Plot erhalten. Ich kann die Grafik jedoch nicht als Bild speichern, da beim Speichern ein Fehler aufgetreten ist.

 

Jede Hilfe wäre toll. Vielen Dank.

 

 

 

<BR />Open("C:\jmp_data\NamesData.jmp", window bounds(600, 50, 500, 400), window state(maximized)); 

window_DATA = New Window("NAMES SHOW", Bivariate(Y(:Name("AGES")), X(:Name("GENDER")), Fit Line({Line Color({100, 50, 50})}))) << Maximize Display << Set Window Icon("FitYByX"); <BR />
window_DATA << save picture( "C:\jmp_data\NamesAge.JPG", JPEG );

 

Re: Speichern Sie das bivariate Diagramm in JPEG

Offensichtlich funktioniert die Meldung "Bild speichern" zumindest in 13.2.1, ist aber nicht dokumentiert. Zumindest für mich funktioniert das Hinzufügen von Klammern zum ursprünglichen Code.

Re: Speichern Sie das bivariate Diagramm in JPEG

Das Fensterobjekt verfügt nicht über eine Nachricht zum Speichern von Bildern.  Im Skriptindex finden Sie die Meldungen, die an das Fensterobjekt übergeben werden können.  Sie müssen ein Objekt innerhalb des Fensters speichern, für das die Nachricht "Bild speichern" unterstützt wird. Hier ist eine mögliche Lösung

Names Default to Here( 1 );
Open(
 "C:\jmp_data\NamesData.jmp",
 window bounds( 600, 50, 500, 400 ),
 window state( maximized )
); 

window_DATA = New Window( "NAMES SHOW",
 Biv = Bivariate(
  Y( :Name( "AGES" ) ),
  X( :Name( "GENDER" ) ),
  Fit Line( {Line Color( {100, 50, 50} )} )
 )
) << Maximize Display << Set Window Icon( "FitYByX" );
report( Biv ) << save picture( "C:\jmp_data\NamesAge.JPG", JPEG );

Re: Speichern Sie das bivariate Diagramm in JPEG

Ich gehe davon aus, dass der Fehler, den Sie erhalten, ein Skriptobjekt benötigt.  Jetzt senden Sie eine Nachricht an das Fenster und speichern das Ergebnis der gesendeten Nachricht in window_DATA.  Sie möchten stattdessen einen Verweis auf das Fenster selbst speichern und dann eine Nachricht an das Fenster senden.  Zwei Optionen sind:

1. Tun Sie alles in einer "Zeile", ähnlich wie Ihr Code jetzt, aber stellen Sie sicher, dass die Variable definiert ist, bevor Sie eine Nachricht an das Fenster senden
2. Tun Sie dies in zwei Zeilen.

Ich empfehle letzteres, da es besser lesbar ist.

Names default to here( 1 );

dt = Open("$Sample_data/iris.jmp"); 

//All at once
( window_DATA_1 = New Window( "NAMES SHOW", 
 Bivariate( 
  Y( :Name( "Sepal length" ) ), 
  X( :Name( "Petal length" ) ), 
  Fit Line( {Line Color( {100, 50, 50} )} )
 ) 
) ) << Maximize Display << Set Window Icon( "FitYByX" );

window_DATA_1 << save picture( "$Desktop\Picture_1.JPG", JPEG );

//In two steps
window_DATA_2 = New Window( "NAMES SHOW", 
 Bivariate( 
  Y( :Name( "Sepal length" ) ), 
  X( :Name( "Petal length" ) ), 
  Fit Line( {Line Color( {100, 50, 50} )} )
 ) 
);

window_DATA_2 << Maximize Display << Set Window Icon( "FitYByX" );

window_DATA_2 << save picture( "$Desktop\Picture_2.JPG", JPEG );