49520_fr-FR

liliconcom

Enregistrer le tracé bivarié au format JPEG

Salut, j'ai pu obtenir l'intrigue bivariée. Mais je ne parviens pas à enregistrer l’intrigue sous forme d’image, car j’ai commis une erreur lors de la sauvegarde.

 

Toute aide est la bienvenue. Merci.

 

 

 

<BR />Open("C:\jmp_data\NamesData.jmp", window bounds(600, 50, 500, 400), window state(maximized)); 

window_DATA = New Window("NAMES SHOW", Bivariate(Y(:Name("AGES")), X(:Name("GENDER")), Fit Line({Line Color({100, 50, 50})}))) << Maximize Display << Set Window Icon("FitYByX"); <BR />
window_DATA << save picture( "C:\jmp_data\NamesAge.JPG", JPEG );

 

Re: Enregistrer le tracé bivarié au format JPEG

Apparemment, au moins dans 13.2.1, le message Enregistrer une image fonctionne mais n’est pas documenté. Au moins pour moi, ajouter des parenthèses au code original fonctionne.

Re: Enregistrer le tracé bivarié au format JPEG

L'objet Window ne dispose pas d'un message Enregistrer une image.  Reportez-vous à l'index de script pour connaître les messages pouvant être transmis à l'objet Window.  Ce que vous devez faire est de sauvegarder un objet dans la fenêtre qui prend en charge le message Enregistrer une image. Voici une solution possible

Names Default to Here( 1 );
Open(
 "C:\jmp_data\NamesData.jmp",
 window bounds( 600, 50, 500, 400 ),
 window state( maximized )
); 

window_DATA = New Window( "NAMES SHOW",
 Biv = Bivariate(
  Y( :Name( "AGES" ) ),
  X( :Name( "GENDER" ) ),
  Fit Line( {Line Color( {100, 50, 50} )} )
 )
) << Maximize Display << Set Window Icon( "FitYByX" );
report( Biv ) << save picture( "C:\jmp_data\NamesAge.JPG", JPEG );

Re: Enregistrer le tracé bivarié au format JPEG

Je suppose que l'erreur que vous obtenez concerne le besoin d'un objet scriptable.  Pour le moment, vous envoyez un message à la fenêtre et enregistrez le résultat du message envoyé dans window_DATA.  Au lieu de cela, vous souhaitez enregistrer une référence à la fenêtre elle-même, puis lui envoyer un message.  Deux options sont à:

1. Faites tout cela en une "ligne", semblable à votre code actuel, mais utilisez l'ordre des opérations pour vous assurer que la variable est définie avant d'envoyer un message à la fenêtre, ou
2. Faites cela en deux lignes.

Je recommande ce dernier car il est plus lisible.

Names default to here( 1 );

dt = Open("$Sample_data/iris.jmp"); 

//All at once
( window_DATA_1 = New Window( "NAMES SHOW", 
 Bivariate( 
  Y( :Name( "Sepal length" ) ), 
  X( :Name( "Petal length" ) ), 
  Fit Line( {Line Color( {100, 50, 50} )} )
 ) 
) ) << Maximize Display << Set Window Icon( "FitYByX" );

window_DATA_1 << save picture( "$Desktop\Picture_1.JPG", JPEG );

//In two steps
window_DATA_2 = New Window( "NAMES SHOW", 
 Bivariate( 
  Y( :Name( "Sepal length" ) ), 
  X( :Name( "Petal length" ) ), 
  Fit Line( {Line Color( {100, 50, 50} )} )
 ) 
);

window_DATA_2 << Maximize Display << Set Window Icon( "FitYByX" );

window_DATA_2 << save picture( "$Desktop\Picture_2.JPG", JPEG );