46133_de-DE

liliconcom

So ändern Sie die X-Achse der Steuerungskarte im Prozess-Screening

Durch das Prozess-Screening bekomme ich schnell die Prozessleistungskurve, die die 2x2-Matrix aus stabil / instabil und konform / nicht konform anzeigt, um zu ermitteln, wo ich meine Aufmerksamkeit auf Verbesserungsbemühungen richten muss. Das ist sehr nützlich.

Ein Beispiel ist beigefügt.

Da die 12 Merkmale in der Anlage unterschiedliche Anzahlen von Daten haben, sehe ich, dass die standardmäßig erstellten Steuerungsdiagramme immer X-Achsen haben, deren Länge der Anzahl der Zeilen in der Tabelle entspricht.

In angehängtem z Das Merkmal Sieben hat 583 Daten, aber das Merkmal Neun nur 79 Daten.

Bei der Erstellung des Kontrolldiagramms für Merkmal Neun werden die 583-Daten standardmäßig mit einer X-Achse konvergiert. Diese Präsentation ist nicht ideal, da ich zunächst die x-Achse verändere, aber für viele Diagramme ist dies dann zeitaufwändig.

Kann jemand raten, wie ich Scripting oder eine andere Option verwende, um die X-Achsen automatisch so konfigurieren zu lassen, dass sie die Anzahl der Daten widerspiegeln, die tatsächlich hinter den einzelnen Merkmalen in jeder Spalte stehen? Es wäre schön zu wissen, wie das gemacht wird, damit die Bilder, die erstellt wurden, um mehr Einblick in die Daten zu erhalten, so schnell wie möglich so informativ wie möglich sind.

Ich habe es gerade überprüft und die Frage würde auch auf Control Chart Builder zutreffen, dh welche Operation an den Spalten ausgeführt werden muss, damit jede X-Achse auf die Anzahl der Zeilen mit tatsächlichen Daten skaliert wird.

Betreff: So ändern Sie die X-Achse der Steuerungskarte im Prozess-Screening

Hallo,

 

Ich dachte, ich würde das hier posten, falls jemand es nützlich fand.  Eine andere Möglichkeit, dies zu erreichen, ist das Erstellen einer neuen Datentabelle, bei der die Prozesse gestapelt und die fehlenden Werte aus der gestapelten Tabelle entfernt werden.  Anschließend können Sie die Spalte Gruppierung in Process Screening verwenden, um die Tabelle in separate Prozesse aufzuteilen.  (Beachten Sie, dass Sie auch eine Tabelle mit Spezifikationsgrenzen erstellen müssen, um diese Methode verwenden zu können, wenn Sie die Fähigkeitsberechnungen durchführen möchten, da die Spalteneigenschaften in der gestapelten Tabelle verschwinden. ) Die folgende JSL demonstriert, wie das geht:

 

dt = Data Table("Process Screening Example");
dtStack = dt << Stack(
 columns(
  :Characteristic One,
  :Characteristic Two,
  :Characteristic Three,
  :Characteristic Four,
  :Characteristic Five,
  :Characteristic Six,
  :Characteristic Seven,
  :Characteristic Eight,
  :Characteristic Nine,
  :Characteristic Ten,
  :Characteristic Eleven,
  :Characteristic Twelve
 ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Data" ),
 Output Table( "Stacked Process Screening Example" )
);

dtStack << select where (isMissing(:Data));
dtStack << delete rows;

 obj = dt<< Manage Spec Limits(
 Y(
  :Characteristic One,
  :Characteristic Two,
  :Characteristic Three,
  :Characteristic Four,
  :Characteristic Five,
  :Characteristic Six,
  :Characteristic Seven,
  :Characteristic Eight,
  :Characteristic Nine,
  :Characteristic Ten,
  :Characteristic Eleven,
  :Characteristic Twelve
 )
);
dtLimits = obj << Save to Tall Spec Limits Table;


obj2 = dtStack << Process Screening(
 Y( :Data ),
 Grouping( :Label ),
 Control Chart Type( "Indiv and MR" ),
 Use Limits Table(
  1,
  dtLimits,
  Grouping( :Variable ),
  LSL( :LSL ),
  USL( :USL ),
  Target( :Target ),
  Go
 )
);

obj2 << select all;
obj2 << control charts for selected items;

 

Wenn Sie mit Control Chart Builder nur dasselbe tun möchten, ohne vorher Process Screening zu starten, können Sie die folgende JSL verwenden:

 

dt = Data Table("Process Screening Example");
dtStack = dt << Stack(
 columns(
  :Characteristic One,
  :Characteristic Two,
  :Characteristic Three,
  :Characteristic Four,
  :Characteristic Five,
  :Characteristic Six,
  :Characteristic Seven,
  :Characteristic Eight,
  :Characteristic Nine,
  :Characteristic Ten,
  :Characteristic Eleven,
  :Characteristic Twelve
 ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Data" ),
 Output Table( "Stacked Process Screening Example" )
);
dtStack << select where (isMissing(:Data));
dtStack << delete rows;
obj = dtStack << Control Chart Builder( Variables( Y( :Data )), By( :Label  ) );

 

Betreff: So ändern Sie die X-Achse der Steuerungskarte im Prozess-Screening

Vielen Dank!

Betreff: So ändern Sie die X-Achse der Steuerungskarte im Prozess-Screening

Mir ist keine Spalteneigenschaft bekannt, mit der dies behoben werden könnte, aber dies kann mit JSL erfolgen.

 

Hier ist ein Beispielskript, das die einzelnen Kontrolldiagramme durchläuft und die X-Achse an die Anzahl der Beobachtungen anpasst.

dt = Data Table("Process Screening Example");
dt << Process Screening(
    Y(
        :Characteristic One,
        :Characteristic Two,
        :Characteristic Three,
        :Characteristic Four,
        :Characteristic Five,
        :Characteristic Six,
        :Characteristic Seven,
        :Characteristic Eight,
        :Characteristic Nine,
        :Characteristic Ten,
        :Characteristic Eleven,
        :Characteristic Twelve
    ),
    Control Chart Type("Indiv and MR"),
    Process Performance Graph(1),
    Test 2(1),
    Ppk Capability Boundary(1),
    Stability Ratio Boundary(1.2),
    Select All,
    Control Charts for Selected Items,
    SendToReport(Dispatch({"Process Performance Graph"}, "ProcessScreening Graph", FrameBox, {Frame Size(553, 424)}))
);

//get list of Control Chart top Outline Boxes
obs = Current Report() << topparent << xpath("//ListBox/OutlineBox");

// Set x-axis max after each N (retrieved from the "Porcess Summary" boxes)
For(i = 1, i <= N Items(obs), i++,
    psum = obs[i][Outline Box("Process Summary")];
    nloc = Loc((psum << xpath("//StringColBox"))[1] << get, "N")[1]; // locate row of "N"
    n = (psum << xpath("//NumberColBox"))[1][nloc]; // get "N"
    (obs[i] << xpath("//AxisBox"))[1] << Max(n + 0.5); // set max
);