53247_es-ES

liliconcom

cómo calcular el rendimiento para muchas columnas con límites de especificaciones integrados

Hola,

Tengo más de 60 columnas donde los límites de especificaciones individuales están integrados en las propiedades de la columna. Me gusta calcular el rendimiento de cada fila como Pasa/Falla. Agradezco cualquier script que haga esto. Revisé la discusión sobre JMP y encontré un script que sí produce resultados, pero se supone que cada columna es aprobada o reprobada (1 o 0). Gracias

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

Gran guión, muy útil.¿Se pregunta si esto podría adaptarse para agregar una tercera categoría donde faltan datos?

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

Jim,

 

Este script lleva bastante tiempo en el foro. Me gusta y para 50 o 60 columnas funciona bien. Recientemente intenté generar un conjunto de estructuras de prueba PCM donde tengo más de 1000 columnas. Descubrí que la fórmula MIN() parece estar fallando. ¿Tiene alguna idea sobre los límites de las columnas u otros límites de variables que puedan limitar la cantidad de argumentos que puedo usar en la fórmula? Tus pensamientos serían apreciados

 

Gracias,

ruso

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

Este script asignará "Falta" en la columna final "Fila aprobada/fallada" si faltan 1 o más valores.

 

foundCols = "";

// Loop across the columns and generate the test pass/fails
For( i = 1, i <= N Items( colList ), i++,
 spec = Column( EVALdt, colList[i] ) << get property( "Spec Limits" );
 EVALdt << clear select;
 If( Is Empty( spec ) == 0,
 
  EVALdt << New Column( (Column( EVALdt, colList[i] ) << get name) || " Pass/Fail" );
  
  If( Is Missing( Try( spec["LSL"], . ) ) == 0,
   EVALdt << select where( As Column( EVALdt, colList[i] ) < spec["LSL"] );
   Try( Column( EVALdt, N Cols( EVALdt ) )[EVALdt << get selected rows] = 0 );
  );
  
  If( Is Missing( Try( spec["USL"], . ) ) == 0,
   EVALdt << select where( As Column( EVALdt, colList[i] ) > spec["USL"], current selection( "extend" ) );
   Try( Column( EVALdt, N Cols( EVALdt ) )[EVALdt << get selected rows] = 0 );
  );
  
  EVALdt << select where( IsMissing( As Column( EVALdt, colList[i] ) ), current selection( "extend" ) );
  
  EVALdt << invert row selection;
  
  Try( Column( EVALdt, N Cols( EVALdt ) )[EVALdt << get selected rows] = 1 );
  
  Column( EVALdt, N Cols( EVALdt ) ) << set property( "Value Labels", {0 = "Fail", 1 = "Pass"} );
  If( foundCols == "",
   foundCols = ":Name(\!"" || (Column( EVALdt, colList[i] ) << get name) || " Pass/Fail\!")",
   foundCols = foundCols || ", " || ":Name(\!"" || (Column( EVALdt, colList[i] ) << get name) || " Pass/Fail\!")"
  );
 );
);

// Create the Row Missing/Pass/Fail
Eval( Parse( "EVALdt << New Column( \!"Row Pass/Fail\!", formula( If( N Missing("||foundCols||") > 1, \!"Missing\!", Min(" || foundCols || " ) == 1, \!"Pass\!", \!"Fail\!" ) ))" ) );

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

@txnelson ,

Este script está resultando muy útil. Gracias. Encontré una cosa que todavía no he podido corregir. Si falta un valor, el script lo marca como aprobado cuando invierte la selección y asigna un valor de 1. Preferiría que asignara "Falta", pero todo lo que he probado no funciona.

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

Gracias Jim. Ahora funciona. Este es un gran guión. Se puede generalizar a muchas columnas. Jugaré más con él. Gracias de nuevo.

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

Mi error, agrega esta línea.

colNamesList={"Parm 1","Parm 2"};

antes de la definición de la función setPassFail.

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

Gracias Jim. Ejecuté el script y ColNamesList no está definido y obtuve un error. Se crea la tabla de rendimiento.

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

Gracias, ¡no puedo esperar para probarlo!

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

A continuación se muestra un script que es muy básico, pero un buen punto de partida para el desarrollo de una calculadora de rendimiento interactiva.Su requisito es una idea muy buena.Tal vez pueda desarrollar y agregar al Intercambio de archivos un nuevo complemento, o tal vez alguien más lo haga.Pero aquí está mi guión de punto de partida:

Names Default To Here( 1 );

// Create a sample data table
dt = New Table( "Yield",
 Add Rows( 40 ),
 New Column( "Parm 1",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 5, 0 ),
  Set Property( "Spec Limits", {LSL( 57 ), USL( 67 ), Show Limits( 0 )} ),
  Set Values(
   [59, 61, 55, 66, 52, 60, 61, 51, 60, 61, 56, 65, 63, 58, 59, 61, 62, 65, 63, 62, 63, 64, 65, 64, 68, 64, 69, 62, 64, 67, 65, 66,
   62, 66, 65, 60, 68, 62, 68, 70]
  )
 ),
 New Column( "Parm 2",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 5, 0 ),
  Set Property( "Spec Limits", {LSL( 80 ), USL( 140 ), Show Limits( 0 )} ),
  Set Values(
   [95, 123, 74, 145, 64, 84, 128, 79, 112, 107, 67, 98, 105, 95, 79, 81, 91, 142, 84, 85, 93, 99, 119, 92, 112, 99, 113, 92, 112,
   128, 111, 105, 104, 106, 112, 115, 128, 116, 134, 172]
  )
 ),
 New Column( "Parm 1 Pass/Fail",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Value Labels( {0 = "Fail", 1 = "Pass"} ),
  Use Value Labels( 1 ),
  Set Values(
   [1, 1, 0, 1, 0, 1, 1, 0, 1, 1, 0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 1, 0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0, 1, 0, 0]
  )
 ),
 New Column( "Parm 2 Pass/Fail",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Value Labels( {0 = "Fail", 1 = "Pass"} ),
  Use Value Labels( 1 ),
  Set Values(
   [1, 1, 0, 0, 0, 1, 1, 0, 1, 1, 0, 1, 1, 1, 0, 1, 1, 0, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 0]
  )
 )
);

// A function to set the Pass/Fail columns based upon the current Spec Limits
setPassFail = Function( {Parm},
 USL = (Column( dt, parm ) << get property( "Spec Limits" ))["USL"];
 LSL = (Column( dt, parm ) << get property( "Spec Limits" ))["LSL"];
 Column( dt, parm || " Pass/Fail" )[dt << get rows where( As Column( dt, parm ) >= LSL & As Column( dt, parm ) <= USL )] = 1;
 Column( dt, parm || " Pass/Fail" )[dt << get rows where( As Column( dt, parm ) < LSL | As Column( dt, parm ) > USL )] = 0;
);

//Calculate  the yield for all Pass/Fail columns
calculateYield = Function( {},
 overallYield = 0;
 numberOfRowsThatPassed = 0;
 numberOfRowsThatFailed = 0;

 For( i = 1, i <= N Rows( dt ), i++,
  If( Sum( :Name( "Parm 1 Pass/Fail" )[i], :Name( "Parm 2 Pass/Fail" )[i] ) == N Items( colNamesList ),
   numberOfRowsThatPassed++,
   numberOfRowsThatFailed
   ++)
 );

 overallYield = numberOfRowsThatPassed / (numberOfRowsThatPassed + numberOfRowsThatFailed);
);

// Display the Yield Changing Window
nw = New Window( "Interactive Yield Calculation",
 Lineup Box( N Col( 2 ),
  V List Box(
   Text Box( "Parm 1" ),
   p1Upper = Col Maximum( :Name( "Parm 1" ) );
   p1Lower = Col Minimum( :Name( "Parm 1" ) );
   p1 = Range Slider Box(
    Col Mean( :Name( "Parm 1" ) ) - 6 * Col Std Dev( :Name( "Parm 1" ) ),
    Col Mean( :Name( "Parm 1" ) ) + 6 * Col Std Dev( :Name( "Parm 1" ) ),
    p1Lower,
    p1Upper,
    Eval(
     Substitute(
       Expr(
        :Name( "Parm 1" ) << set property( "Spec Limits", {LSL( _LSL_ ), USL( _USL_ ), Show Limits( 0 )} )
       ),
      Expr( _LSL_ ), p1Lower,
      Expr( _USL_ ), p1Upper
     )
    );
    returned = setPassFail( "Parm 1" );
    cYield = calculateYield();
    yieldVal << set( cYield );
   );,
   Text Box( "Parm 2" ),
   p2Upper = Col Maximum( :Name( "Parm 2" ) );
   p2Lower = Col Minimum( :Name( "Parm 2" ) );
   p2 = Range Slider Box(
    Col Mean( :Name( "Parm 2" ) ) - 6 * Col Std Dev( :Name( "Parm 2" ) ),
    Col Mean( :Name( "Parm 2" ) ) + 6 * Col Std Dev( :Name( "Parm 2" ) ),
    p2Lower,
    p2Upper,
    Eval(
     Substitute(
       Expr(
        :Name( "Parm 2" ) << set property( "Spec Limits", {LSL( _LSL_ ), USL( _USL_ ), Show Limits( 0 )} )
       ),
      Expr( _LSL_ ), p2Lower,
      Expr( _USL_ ), p2Upper
     )
    );
    returned = setPassFail( "Parm 2" );
    cYield = calculateYield();
    yieldVal << set( cYield );
   );,

  ),
  V List Box( Text Box( "Yield" ), yieldVal = Number Edit Box() )
 ),
 cYield = calculateYield();
 yieldVal << set( cYield );
);

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

Detalle adicional, tengo entre 75 y 150 parámetros y muy pocos tienen los mismos límites. En una experiencia reciente, tengo tres parámetros que impulsan el rendimiento y una cantidad limitada de alivio de especificaciones que puedo esperar recibir. Necesito saber qué combinación de cambios de especificaciones producirá la mayor mejora y, al mismo tiempo, minimizará la magnitud de los cambios.

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integradosLo que me gustaría poder hacer es hacer un análisis hipotético en el que pueda cambiar un par de especificaciones, volver a examinar los datos y obtener un número de rendimiento.Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

La definición de límites de especificación normalmente no contiene su cálculo dinámico.Se establecen en función de límites de diseño, etc.Aparte de eso, con respecto a su pregunta, ¿imagina establecer los límites dinámicamente para todas las columnas (parámetros) al mismo tiempo?Es decir, ¿los límites serán los mismos para cada parámetro?¿O configurarías cada uno individualmente?El uso de un filtro de datos junto con fórmulas de columnas podría manejar su solicitud.

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

No entiendo por qué esta funcionalidad no está integrada en JMP, pero ¿cómo podría cambiarse este script para que las columnas de aprobación/rechazo sean dinámicas? Me gustaría poder ajustar las especificaciones para determinar el efecto sobre el rendimiento. Tal como está ahora, tendría que eliminar las columnas agregadas cada vez que quisiera reevaluar el rendimiento.

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

Gracias Jim. Ahora funciona.

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

Mi error, un ")" quedó fuera de la última declaración.Debería ser:

Eval( Parse( "dt << New Column( \!"Row Pass/Fail\!", formula( If( Min(" || foundCols || " ) == 1, 1, 0 ) ))" ) );

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

Gracias Jim. Esto es exactamente lo que quería.

 

Ejecuté el script y encontré este error. Se crea una columna con el título "Fila aprobada/fallada" y es todo cero.

 

Fin inesperado de la entrada. Quizás falte un "," o ")".

Intentando analizar los argumentos de la función "Nueva columna".

Línea 1 Columna 3272: ...s/Fail") ) == 1, 1, 0 ) ) ►...

 

Resolución del problema con la fórmula para el ID de oblea de columna en el ID de lote:

Columna ("Fila pasa/falla")

 

Gracias por su apoyo continuo.

Re: cómo calcular el rendimiento de muchas columnas con límites de especificaciones integrados

Aquí hay un script que creará nuevas columnas que contienen numéricamente 0/1 y se muestran como Fallo/Aprobado.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Semiconductor Capability.jmp" );

// Get all numeric columns
colList = dt << get column names( numeric, string );

foundCols = "";

// Loop across the columns and generate the test pass/fails
For( i = 1, i <= N Items( colList ), i++,
 spec = Column( dt, colList[i] ) << get property( "Spec Limits" );
 dt << clear select;
 If( Is Empty( spec ) == 0,
  dt << New Column( (Column( dt, colList[i] ) << get name) || " Pass/Fail" );
  If( Is Missing( Try( spec["LSL"], . ) ) == 0,
   dt << select where( As Column( dt, colList[i] ) < spec["LSL"] );
   Try( Column( dt, N Cols( dt ) )[dt << get selected rows] = 0 );
  );
  If( Is Missing( Try( spec["USL"], . ) ) == 0,
   dt << select where( As Column( dt, colList[i] ) > spec["USL"], current selection( "extend" ) );
   Try( Column( dt, N Cols( dt ) )[dt << get selected rows] = 0 );
  );
  dt << invert row selection;
  Try( Column( dt, N Cols( dt ) )[dt << get selected rows] = 1 );
  Column( dt, N Cols( dt ) ) << set property( "Value Labels", {0 = "Fail", 1 = "Pass"} );
  If( foundCols == "",
   foundCols = ":Name(\!"" || (Column( dt, colList[i] ) << get name) || " Pass/Fail\!")",
   foundCols = foundCols || ", " || ":Name(\!"" || (Column( dt, colList[i] ) << get name) || " Pass/Fail\!")"
  );
 );
);

// Create the Row Pass/Fail
Eval( Parse( "dt << New Column( \!"Row Pass/Fail\!", formula( If( Min(" || foundCols || " ) == 1, 1, 0 ) )" ) );