<meta http-equiv="Content-Type" content="text/html; charset=UTF-8" />Wie erstelle ich in JMP eine einfache Typnummernzeile für die Grundschule? Ich möchte Zahlen wie 0,8, 0,9, 0,92, 0,94 in einer Zahlenzeile darstellen. Ich habe ein Diagramm erstellt, das Datenstatistiken mit den Optionen für horizontales und Punktdiagramm verwendet. Wie kann ich die Y-Achse loswerden, sodass die Werte nur auf der X-Achse dargestellt werden?
die gleiche Idee mit JSL. Sieht scharf aus, wenn der Diagrammhintergrund mit dem Fensterhintergrund übereinstimmt.
Erstellen von anonymen Diagrammen in JMP 8 - JMP-Blog hat einige Geheimnisse zum Entfernen von zusätzlichen Zeilen und Text aus einem Diagramm, die hier wiederverwendet werden.
JMP 11 lässt die vertikale Achse sehr kurz sein, was das Erscheinungsbild verbessert. Zwei Referenzlinien, beide auf Null, sehen aus wie Achsen.
dt = New Table( "Untitled", New Column( "x", Set Values( [0.1, 0.8, 0.7, 0.3, 0.4] ) ) );
xvals = dt:x << get values;
yvals = J( N Rows( xvals ), 1, 0 );
New Window( "Number Line",
BorderBox(left(10),top(10),right(10),bottom(10), vlistbox(
Text Box( "Points on a number line" ),
Spacer Box( size( 10, 50 ) ),
g = Graph Box( Frame Size( 500, 7 ),
X Scale( -0.1, 1.1 ), Y Scale( -1, 1 ),
yname( " " ), Marker Size( 2 ),
yaxis( show major ticks( false ), show minor ticks( false ),
show labels( false ), Inside Ticks( 1 ),
Add Ref Line( 0.0, Solid, "Black", "", 1 ) ),
xaxis( show major ticks( false ), show minor ticks( false ),
show labels( true ), Add Ref Line( 0.0, Solid, "Black", "", 1 ),
Inside Ticks( 1 ) ),
Marker( Combine States( Marker State( 12 ),color state("red") ), xvals, yvals )
),
Spacer Box( size( 10, 50 ) ),
Text Box( "drag with the axis" )
))
);
// http://blogs.sas.com/content/jmp/2008/11/10/making-anonymous-graphs-in-jmp-8/
g[axis box( 1 )] << remove axis label;
g[axis box( 2 )] << remove axis label;
// hide the inner border
g[frame box( 1 )] << Left( 0 ); // no line on left, etc
g[frame box( 1 )] << Right( 0 );
g[frame box( 1 )] << top( 0 );
g[frame box( 1 )] << bottom( 0 );
// shrink and hide the outer border too
g[Border Box( 1 )] << Left( 0 ); // no space on left, etc
g[Border Box( 1 )] << Right( 0 );
g[Border Box( 1 )] << Top( 0 );
g[Border Box( 1 )] << bottom( 0 );
g[Border Box( 1 )] << sides( 0 ); // draw no sides (1+2+4+8 would be all four sides)
Versuchen Sie den Graph Builder. Ziehen Sie einfach Ihre Spalte auf die X-Achse.
