37286_ja-JP

liliconcom

特定モデルの予測プロットによる実績

こんにちは、

 

他のコラムのモデル（レスポンス）に対応するコラム（型式）があります。

応答列と式を含む列を「予測」として「実際」として考慮して、予測プロットで実際をグラフ化できるかどうかを知りたいのですが。 

モデルがjmpによって定義されているときだけ私はこれらのグラフを見る。

 

前もって感謝します。

再：特定のモデルの予測プロットによる実際YでXをフィットさせることができます。実データをXに、モデルデータをYに入れます。線をフィットさせます（赤い三角形）。勾配はRSの2乗であり、他のプロットを使って残差を調べることができます。

ベスト、

M再：特定のモデルの予測プロットによる実際

これは列式でも可能ですが面倒になります。このスクリプトはうまくいくはずです：

dlg = Column Dialog(
 Title( "Evaluate Model" ),
 yCol = Col List( "Response",
  Data Type( Numeric ),
  Min Col( 1 ),
  Max Col( 1 )
 ),
 mCol = Col List( "Model",
  Data Type( Numeric ),
  Min Col( 1 ),
  Max Col( 1 )
 )
);
If( dlg["Button"] == -1,
 Throw( "User cancelled" );
);
Remove From( dlg );
Eval List( dlg );
dt = Current Data Table();
response = yCol[1] << Get As Matrix;
model = mCol[1] << Get As Matrix;
residual = model - response;
sst = Sum( (response - Mean( response ) )^2 );
sse = Sum( residual^2 );
ssm = sst - sse;
r square = ssm / sst;
dt << New Column( "Residual", Values( residual ) );
New Window( "Evaluate Model",
 dt << Graph Builder(
  Variables( X( mCol[1] ), Y( yCol[1] ) ),
  Elements( Points( X, Y, Legend( 3 ) ) ),
  Show Control Panel( 0 )
 ),
 dt << Graph Builder(
  Variables( X( :Residual ), Y( yCol[1] ) ),
  Elements( Points( X, Y, Legend( 3 ) ) ),
  Show Control Panel( 0 )
 ),
 Text Box( "R square is " || Char( r square ) )
);

再：特定のモデルの予測プロットによる実際

こんにちは、

 

ご回答有難うございます。私は自分の目的をうまく説明していないと思います。 

私がやりたいこと、それは私のモデルを評価することです。可能であれば、モデルのRS2乗値を定義し、予測プロットによって残差を取得します。jmpが最小二乗法の近似を報告するようなものですが、式として定義したモデルを考慮しています。

 

敬具

再：特定のモデルの予測プロットによる実際

解決策は簡単かもしれないと思います。

1. グラフ／グラフビルダーを選択します。
2. 観測された応答を選択して、それをYドロップゾーンにドラッグします。
3. モデル列を選択してXドロップゾーンにドラッグします。

私があなたの要求を過度に単純化したかどうか私に知らせなさい