37286_it-IT

liliconcom

Effettivo in base al grafico previsto di un modello specifico

Ciao,

 

Ho una colonna (tipo formula) che corrisponde al modello di un'altra colonna (risposta).

Vorrei sapere se è possibile rappresentare graficamente il grafico effettivo rispetto a quello previsto considerando come "effettivo" la colonna della risposta e la colonna che contiene la formula come "previsto".

Vedo questi grafici solo quando il modello è definito da jmp.

 

Grazie in anticipo.

Ri: Effettivo in base alla trama prevista di un modello specificoPotresti provare Fit Y di X. Metti i dati reali in X, i dati del modello in Y. Adatta una linea (triangolo rosso). La pendenza è RSquared ed è possibile esaminare i residui utilizzando gli altri grafici.

Migliore,

MRi: Effettivo in base alla trama prevista di un modello specifico

Questo potrebbe essere fatto con le formule di colonna ma diventerebbe disordinato. Questo script dovrebbe fare il trucco:

dlg = Column Dialog(
 Title( "Evaluate Model" ),
 yCol = Col List( "Response",
  Data Type( Numeric ),
  Min Col( 1 ),
  Max Col( 1 )
 ),
 mCol = Col List( "Model",
  Data Type( Numeric ),
  Min Col( 1 ),
  Max Col( 1 )
 )
);
If( dlg["Button"] == -1,
 Throw( "User cancelled" );
);
Remove From( dlg );
Eval List( dlg );
dt = Current Data Table();
response = yCol[1] << Get As Matrix;
model = mCol[1] << Get As Matrix;
residual = model - response;
sst = Sum( (response - Mean( response ) )^2 );
sse = Sum( residual^2 );
ssm = sst - sse;
r square = ssm / sst;
dt << New Column( "Residual", Values( residual ) );
New Window( "Evaluate Model",
 dt << Graph Builder(
  Variables( X( mCol[1] ), Y( yCol[1] ) ),
  Elements( Points( X, Y, Legend( 3 ) ) ),
  Show Control Panel( 0 )
 ),
 dt << Graph Builder(
  Variables( X( :Residual ), Y( yCol[1] ) ),
  Elements( Points( X, Y, Legend( 3 ) ) ),
  Show Control Panel( 0 )
 ),
 Text Box( "R square is " || Char( r square ) )
);

Ri: Effettivo in base alla trama prevista di un modello specifico

Ciao,

 

Grazie per la tua risposta. Penso di non aver spiegato molto bene il mio obiettivo.

Quello che voglio fare è valutare il mio modello. Vorrei definire il valore RSquare del modello (se possibile) e ottenere il residuo dalla trama prevista. Qualcosa di simile al report jmp per i minimi quadrati fit ma considerando il modello che ho definito come una formula.

 

Cordiali saluti

Ri: Effettivo in base alla trama prevista di un modello specifico

Penso che la soluzione potrebbe essere semplice.

1. Selezionare Grafico > Generatore di grafici.
2. Seleziona la risposta osservata e trascinala nella zona di rilascio Y.
3. Seleziona la colonna del modello e trascinala nella zona di rilascio X.

Fammi sapere se ho semplificato eccessivamente la tua richiesta.