37286_fr-FR

liliconcom

Réel par tracé prédit d'un modèle spécifique

Bonjour,

 

J'ai une colonne (type formule) qui correspond au modèle d'une autre colonne (réponse).

Je voudrais savoir s'il est possible de représenter graphiquement le tracé réel par prédit en considérant comme "réel" la colonne de réponse et la colonne qui contient la formule comme "prédite".

Je ne vois ces graphiques que lorsque le modèle est défini par jmp.

 

Merci d'avance.

Re : Réel par tracé prédit d'un modèle spécifiqueVous pouvez essayer Fit Y by X. Mettez les données réelles dans X, les données du modèle dans Y. Monter une ligne (triangle rouge). La pente est le RSquared et vous pouvez examiner les résidus en utilisant les autres parcelles.

Meilleur,

MRe : Réel par tracé prédit d'un modèle spécifique

Cela pourrait être fait avec des formules de colonne, mais cela deviendrait désordonné. Ce script devrait faire l'affaire :

dlg = Column Dialog(
 Title( "Evaluate Model" ),
 yCol = Col List( "Response",
  Data Type( Numeric ),
  Min Col( 1 ),
  Max Col( 1 )
 ),
 mCol = Col List( "Model",
  Data Type( Numeric ),
  Min Col( 1 ),
  Max Col( 1 )
 )
);
If( dlg["Button"] == -1,
 Throw( "User cancelled" );
);
Remove From( dlg );
Eval List( dlg );
dt = Current Data Table();
response = yCol[1] << Get As Matrix;
model = mCol[1] << Get As Matrix;
residual = model - response;
sst = Sum( (response - Mean( response ) )^2 );
sse = Sum( residual^2 );
ssm = sst - sse;
r square = ssm / sst;
dt << New Column( "Residual", Values( residual ) );
New Window( "Evaluate Model",
 dt << Graph Builder(
  Variables( X( mCol[1] ), Y( yCol[1] ) ),
  Elements( Points( X, Y, Legend( 3 ) ) ),
  Show Control Panel( 0 )
 ),
 dt << Graph Builder(
  Variables( X( :Residual ), Y( yCol[1] ) ),
  Elements( Points( X, Y, Legend( 3 ) ) ),
  Show Control Panel( 0 )
 ),
 Text Box( "R square is " || Char( r square ) )
);

Re : Réel par tracé prédit d'un modèle spécifique

Bonjour,

 

Merci pour votre réponse. Je pense que je n'ai pas très bien expliqué mon objectif.

Ce que je veux faire, c'est évaluer mon modèle. Je voudrais définir la valeur RSquare du modèle (si c'est possible) et obtenir le résidu par parcelle prédite. Quelque chose comme le rapport jmp pour l'ajustement des moindres carrés mais en considérant le modèle que j'ai défini comme une formule.

 

Bien à vous

Re : Réel par tracé prédit d'un modèle spécifique

Je pense que la solution pourrait être simple.

1. Sélectionnez Graphique > Générateur de graphiques.
2. Sélectionnez la réponse observée et faites-la glisser vers la zone de dépôt Y.
3. Sélectionnez la colonne de modèle et faites-la glisser vers la zone de dépôt X.

Faites-moi savoir si j'ai trop simplifié votre demande.