¿Cómo hacer un cálculo en JMP?
Hay dos dimensiones de datos, por ejemplo, actual y tiempo, luego en JMP Grapher, podemos trazar una curva y ajustarla suavemente, para más detalles, vea la foto a continuación.
¿Cuánta cantidad eléctrica será? eso significa que me gustaría saber cómo calcular el área bajo la curva.
en matemáticas, ¿cómo hacer un cálculo en JMP?
Aquí hay un ejemplo simple de @Mark_Bailey sugerencia de .
Names default to Here(1);
dt = New Table("Example",
Add Rows( 5 ),
New Column( "Time",
Numeric,
"Continuous",
Format( "Best", 12 ),
Set Values( [0, 2, 4, 6, 8] )
),
New Column( "I",
Numeric,
"Continuous",
Format( "Best", 12 ),
Set Values(
[0.303858872597443, 0.22418155030798, 0.202170635461688,
0.181779722721203, 0.148724968294765]
)
)
);
//use bivariate for simplicity
biv = dt << Bivariate(
Y( :I ),
X( :Time ),
Fit Polynomial( 3, {Confid Shaded Indiv( 1 ), Line Color( {212, 73, 88} )} ),
SendToReport(
Dispatch(
{},
"2",
ScaleBox,
{Min( 0 ), Max( 0.45 ), Inc( 0.05 ), Minor Ticks( 1 )}
)
)
);
//get the prediction formula string
fm = report(biv)[OutlineBox("Polynomial ?")][TextEditBox(1)] << get text;
//get the string to the right of the equal sign and convert the string to an expression using Parse()
fm = Parse(Trim(word(2, fm, "=")));
area = Integrate(fm, Time, col minimum(:Time), col maximum(:Time));
Caption("The area under this curve is " || char(area));
Ver Ayuda > Índice de secuencias de comandos y busca Integrar función. Esta función realiza la integración numérica de su expresión (modelo ajustado). Use el botón Ayuda en el índice para obtener más información sobre esta función.
Probablemente necesitará guardar el modelo ajustado como una nueva fórmula de columna y luego usar un script corto para extraer la expresión de la fórmula y usarla como argumento para la función Integrar().
