50471_fr-FR

liliconcom

Extraire les couleurs d'une colonne #rrggbb

Problème

Vous avez les couleurs au format HTML "#RRGGBB" et vous souhaitez les utiliser dans les graphiques JMP. Par exemple, voici le jeu de données que j'ai utilisé pour la stations de métro du monde scatter plot . le Couleur colonne est une colonne de caractères avec six chiffres hexadécimaux, deux pour chacune des composantes de couleur.

 

Solution 1: Couleurs des lignes

Dans une table JMP, chaque ligne peut être associée à quelques attributs, notamment la couleur et la forme du marqueur, appelés collectivement "états de ligne". Pour convertir automatiquement la colonne de texte de couleur en couleur d'états de lignes, j'ai utilisé ce script:

 

For Each Row(
 Color Of() = RGB Color(
  Hex To Number(Substr(:color, 2, 2)),
  Hex To Number(Substr(:color, 4, 2)),
  Hex To Number(Substr(:color, 6, 2))
 );
);

Chaque appel à substr () extrait une séquence hexadécimale de 2 caractères, puis Hex To Number () la convertit en un nombre compris entre 0 et 255. Couleur RVB () combine les trois composants en une valeur de couleur unique et Color Of () lui attribue l'état de la ligne actuelle.

Je mets ce script dans un script de table afin que je puisse le réexécuter lorsque je reçois des données mises à jour.

Avec les couleurs stockées dans les états des lignes, elles seront automatiquement utilisées pour les couleurs des marqueurs de diagramme de dispersion.

 

Solution 2: Couleurs de valeur

Pour les éléments de graphique qui ne correspondent généralement pas à des lignes individuelles, telles que les graphiques à barres et les treemaps, les couleurs des lignes ne vous aideront pas. Cependant, nous pouvons ajouter une propriété Value Colors à Couleur colonne et utilisez-le dans le rôle Couleur du Générateur de graphes, ces couleurs seront utilisées dans le graphique. Pour créer une propriété de colonne Value Colors par programme, commencez par créer une propriété test Value Couleurs et effectuez un script de copie de table sur la table de données pour voir comment JMP enregistre les couleurs de valeurs en JSL. Vous verrez quelque chose comme ça:

 

...
Set Property( "Value Colors",
  {"#000000" = -5425372, "#003399" = -13577875, "#004899" = -4354269,
  "#0063aa" = -13400361, "#006fba" = -2668175, "#0070bc" = -10628061,
  ...})

Dans chaque affectation, le côté gauche correspond à la valeur de données et le côté droit à la représentation sous forme de numéro JSL d'une valeur de couleur, identique au résultat de la fonction Couleur RVB ().

Notre tâche consiste donc à créer une telle expression par programme à l'aide d'expressions JSL, puis à l'envoyer à la table de données pour définir la propriété avec le message Ajouter des propriétés de colonne ().

Voici mon code:

eadd = Expr(
 Column( "color" ) << Add Column Properties( Set Property( "Value Colors", LLL ) )
);

evc = {};
ec = Expr( SSS = CCC );

For Each Row(
 ec2 = Substitute( Name Expr( ec ),
  Expr( SSS ), :color,
  Expr( CCC ),
   RGB Color(
    Hex To Number( Substr( :color, 2, 2 ) ),
    Hex To Number( Substr( :color, 4, 2 ) ),
    Hex To Number( Substr( :color, 6, 2 ) )
   )
 );
 Insert Into( evc, Name Expr( ec2 ) );
);

Substitute Into( eadd, Expr( LLL ), Name Expr( evc ) );

eadd; // evaluates the expression

Par convention, je préfixe les variables d'expression avec "e" et utilise des majuscules pour les modèles de substitution. L'idée de base est de créer une expression avec le formulaire de base à l'aide d'espaces réservés, puis d'utiliser Remplacer pour remplacer les espaces réservés par des valeurs calculées. Mais ici, il y a deux niveaux de substitution en cours. Un pour la commande, eadd , qui a le JE VAIS espace réservé pour la liste des couleurs de valeur, et un pour chaque affectation, ec , qui a des espaces réservés SSS et CCC pour la ficelle et la couleur.

 

Discussion

 Quelle que soit la solution choisie, on peut créer un nuage de points comme celui-ci, qui affiche les couleurs des plus grands métros.

 

Devoirs

Créez des colonnes de formule qui extraient les composants rouge, vert et bleu en colonnes séparées.

Créez des colonnes de formule qui créent des colonnes de teinte, de luminosité et de saturation.

Voir également

Fichiers de données brutes pour les couleurs de métro sur github