78984_ko-KR

liliconcom

루프를 통해 그래프 창 결합

안녕하세요,

 

나는 그래프에 응답 변수가 길고, 각 창이 미리 정의 된 카테고리 인 별도의 창에서 그룹으로 묶고 싶습니다. 그런 다음 모든 보고서 (그래프 창)를 결합하고 대시 보드를 만들고 싶습니다. 윈도우 -> 윈도우 결합 (이전에 다른 목적으로 사용했던)으로 이동하면 리포트가 결합 옵션으로 나열되지 않습니다. 아무도 도와 줄 수 있니?

 

다음은 샘플 데이터 테이블을 사용하여 그래프를 생성하는 데 사용되는 JMP 스크립트입니다. 이 예제에서는 각 항공사에 대해 별도의 그래프 창이 필요하다고 가정 해 보겠습니다.

 

고맙습니다.

Derchieh

 

 

 

 

Names Default to Here(1);

sourcedt = Open("$SAMPLE_DATA\Airline Delays.jmp");

dt = sourcedt << Stack(
 columns( :Elapsed Time, :Arrival Delay, :Distance ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Value" )
);

Summarize(dt, al = By(:Airline));
Summarize(dt, mon = By(:Month));
Summarize(dt, para = By(:Label));


For (j = 1, j <= NItems(al), j++,
 New Window( al[j],
  V List Box(
 
   For (i = 1, i <= NItems(para), i++,
  
    Graph Builder(
     Size(230, 300),
     Fit to Window( "Off" ),
     Show Control Panel(0),
     Variables( X( :Month ), Y( :Value ), Overlay( :Day of Week ) ),
     Elements( Points( X, Y, Legend( 1 ) ) ),
     Where( :Airline == al[j] & :Label == para[i] ),
     SendToReport(
     Dispatch(
      {},
      "Value",
      ScaleBox,
      {Min( -10 ),  Minor Ticks( 0 )}
     ),
     Dispatch( {}, "graph title", TextEditBox, {Set Text( "" )} ),
     Dispatch( {}, "Y title", TextEditBox, {Set Text( para[i] )} )
     )
    ) << report;
   )
  )
 )
);

 

다시 : 루프를 통해 그래프 창 결합

답장을 보내 주셔서 감사합니다. 이제 이해가된다. 감사!

 

다시 : 루프를 통해 그래프 창 결합

실행중인 문제점은 작성한 다른 창에 대한 포인터를 저장하지 않았기 때문입니다.  스크립트 (아래 참조)를 수정하여 작성한 6 개의 창에 대한 참조를 "alWindowList"라는 목록에 저장합니다.  여기에는 창에 대한 6 개의 포인터가 들어 있습니다.  결합 창에서 창을 함께 결합하는 데 사용할 수 있습니다.

나는 또한 당신의 스크립트에서 항공사와 라벨의 표시가 의미있는 방식으로 표시되지 않는다는 것을 알아 차렸고, 따라서 스크립트가 al [j]와 para [ i] 디스플레이.

Names Default To Here( 1 );

sourcedt = Open( "$SAMPLE_DATA\Airline Delays.jmp" );

dt = sourcedt << Stack(
 columns( :Elapsed Time, :Arrival Delay, :Distance ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Value" )
);

Summarize( dt, al = By( :Airline ) );
Summarize( dt, mon = By( :Month ) );
Summarize( dt, para = By( :Label ) );
alWindowList = {};

For( j = 1, j <= N Items( al ), j++,
 nw = New Window( al[j],
  V List Box(
 
   For( i = 1, i <= N Items( para ), i++,
    Eval(
     Substitute(
       Expr(
        Graph Builder(
         Size( 230, 300 ),
         Fit to Window( "Off" ),
         Show Control Panel( 0 ),
         Variables( X( :Month ), Y( :Value ), Overlay( :Day of Week ) ),
         Elements( Points( X, Y, Legend( 1 ) ) ),
         Where( :Airline == __al__ & :Label == __para__ ),
         SendToReport(
          Dispatch( {}, "Value", ScaleBox, {Min( -10 ), Minor Ticks( 0 )} ),
          Dispatch( {}, "graph title", TextEditBox, {Set Text( "" )} ),
          Dispatch( {}, "Y title", TextEditBox, {Set Text( para[i] )} )
         )
        ) << report
       ),
      Expr( __al__ ), al[j],
      Expr( __para__ ), para[i]
     )
    )
   )
  )
 );
 Insert Into( alWindowList, nw );
);

다시 : 루프를 통해 그래프 창 결합

Hi txnelson,

 

다른 컨텍스트에 대해이 (유사한) 코드를 재사용해야하지만 더 이상 작동하지 않는 것 같습니다. 즉, 창 제목은 결합 창 목록이나 대시 보드에 추가 할 수있는 보고서로 표시되지 않습니다. 아래 코드를 다시 실행하면 같은 문제가 발생합니다. 우리는 최근에 14.2 .....로 업그레이드 할 수 있습니까?

 

많은 감사합니다.

Derchieh