78984_ja-JP

liliconcom

ループを介してグラフウィンドウを結合する

こんにちは、

 

私はグラフに対する応答変数の長いリストを持っていて、それぞれのウィンドウがあらかじめ定義されたカテゴリーである別々のウィンドウにそれらをグループ化したいです。それから、すべてのレポート（グラフウィンドウ）を結合してダッシュボードを作成します。ウィンドウ - >ウィンドウの結合（以前はさまざまな目的で使用していた）に移動したときに、レポートが結合のオプションとして表示されません。誰かが喜ばせることができますか？

 

以下は、サンプルデータテーブルを使用してグラフを生成するために使用したJMPスクリプトです。この例では、航空会社ごとに別々のグラフウィンドウが必要だとします。

 

ありがとうございました。

Derchieh

 

 

 

 

Names Default to Here(1);

sourcedt = Open("$SAMPLE_DATA\Airline Delays.jmp");

dt = sourcedt << Stack(
 columns( :Elapsed Time, :Arrival Delay, :Distance ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Value" )
);

Summarize(dt, al = By(:Airline));
Summarize(dt, mon = By(:Month));
Summarize(dt, para = By(:Label));


For (j = 1, j <= NItems(al), j++,
 New Window( al[j],
  V List Box(
 
   For (i = 1, i <= NItems(para), i++,
  
    Graph Builder(
     Size(230, 300),
     Fit to Window( "Off" ),
     Show Control Panel(0),
     Variables( X( :Month ), Y( :Value ), Overlay( :Day of Week ) ),
     Elements( Points( X, Y, Legend( 1 ) ) ),
     Where( :Airline == al[j] & :Label == para[i] ),
     SendToReport(
     Dispatch(
      {},
      "Value",
      ScaleBox,
      {Min( -10 ),  Minor Ticks( 0 )}
     ),
     Dispatch( {}, "graph title", TextEditBox, {Set Text( "" )} ),
     Dispatch( {}, "Y title", TextEditBox, {Set Text( para[i] )} )
     )
    ) << report;
   )
  )
 )
);

 

再：グラフウィンドウをループで結合する

お返事ありがとうございました！わかった。ありがとうございます。

 

再：グラフウィンドウをループで結合する

あなたが遭遇している問題は、あなたがあなたが作成した異なったウィンドウへのポインタを保存していないということです。  私はあなたが作成した6つのウィンドウへの参照を "alWindowList"と呼ばれるリストに保存するためにあなたのスクリプトを修正しました（下記参照）。  ウィンドウへの6つのポインタが含まれています。  ウィンドウを結合するためにCombine Windowで使用できます。

また、私のスクリプトでは、航空会社とラベルの表示が意味のある方法で表示されていないことに気付いたので、al [j]やpara [ではなく実際の値を使用するようにコードを強制します。表示します。

Names Default To Here( 1 );

sourcedt = Open( "$SAMPLE_DATA\Airline Delays.jmp" );

dt = sourcedt << Stack(
 columns( :Elapsed Time, :Arrival Delay, :Distance ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Value" )
);

Summarize( dt, al = By( :Airline ) );
Summarize( dt, mon = By( :Month ) );
Summarize( dt, para = By( :Label ) );
alWindowList = {};

For( j = 1, j <= N Items( al ), j++,
 nw = New Window( al[j],
  V List Box(
 
   For( i = 1, i <= N Items( para ), i++,
    Eval(
     Substitute(
       Expr(
        Graph Builder(
         Size( 230, 300 ),
         Fit to Window( "Off" ),
         Show Control Panel( 0 ),
         Variables( X( :Month ), Y( :Value ), Overlay( :Day of Week ) ),
         Elements( Points( X, Y, Legend( 1 ) ) ),
         Where( :Airline == __al__ & :Label == __para__ ),
         SendToReport(
          Dispatch( {}, "Value", ScaleBox, {Min( -10 ), Minor Ticks( 0 )} ),
          Dispatch( {}, "graph title", TextEditBox, {Set Text( "" )} ),
          Dispatch( {}, "Y title", TextEditBox, {Set Text( para[i] )} )
         )
        ) << report
       ),
      Expr( __al__ ), al[j],
      Expr( __para__ ), para[i]
     )
    )
   )
  )
 );
 Insert Into( alWindowList, nw );
);

再：グラフウィンドウをループで結合する

こんにちはtxnelson、

 

この（似た）コードを別のコンテキストに再利用する必要がありますが、もううまくいきそうにはありません。つまり、ウィンドウのタイトルは、ウィンドウの組み合わせのリストにも、ダッシュボードに追加できるレポートとしても表示されません。私は以下にあなたのコードを再実行します、同じ問題が存在します。私たちは最近14.2にアップグレードしました.....それが問題になるでしょうか？

 

どうもありがとう。

Derchieh