78984_zh-TW

liliconcom

通過循環組合圖形窗口

嗨，

 

我有一長串的響應變量列表，我想將它們分組在單獨的窗口中，其中每個窗口都是預定義的類別。然後我想組合所有報告（圖形窗口）並創建儀表板。當我轉到Window - >組合Windows（我以前用過不同的目的）時，報告不會列為組合選項。有人可以幫忙嗎？

 

下面是我用於生成帶有示例數據表的圖形的JMP腳本。對於此示例，假設我們需要為每個航空公司設置單獨的圖形窗口。

 

謝謝。

Derchieh

 

 

 

 

Names Default to Here(1);

sourcedt = Open("$SAMPLE_DATA\Airline Delays.jmp");

dt = sourcedt << Stack(
 columns( :Elapsed Time, :Arrival Delay, :Distance ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Value" )
);

Summarize(dt, al = By(:Airline));
Summarize(dt, mon = By(:Month));
Summarize(dt, para = By(:Label));


For (j = 1, j <= NItems(al), j++,
 New Window( al[j],
  V List Box(
 
   For (i = 1, i <= NItems(para), i++,
  
    Graph Builder(
     Size(230, 300),
     Fit to Window( "Off" ),
     Show Control Panel(0),
     Variables( X( :Month ), Y( :Value ), Overlay( :Day of Week ) ),
     Elements( Points( X, Y, Legend( 1 ) ) ),
     Where( :Airline == al[j] & :Label == para[i] ),
     SendToReport(
     Dispatch(
      {},
      "Value",
      ScaleBox,
      {Min( -10 ),  Minor Ticks( 0 )}
     ),
     Dispatch( {}, "graph title", TextEditBox, {Set Text( "" )} ),
     Dispatch( {}, "Y title", TextEditBox, {Set Text( para[i] )} )
     )
    ) << report;
   )
  )
 )
);

 

Re：通過循環組合圖形窗口

非常感謝你的回复！我現在明白了。謝謝！

 

Re：通過循環組合圖形窗口

您遇到的問題是您沒有保存指向您創建的不同窗口的指針。  我已經修改了你的腳本（見下文），將你創建的6個窗口的引用保存到名為“alWindowList”的列表中。  它包含指向窗口的六個指針。  它可以在組合窗口中用於將窗口連接在一起。

我還在你的腳本中註意到，航空公司和標籤的顯示沒有以有意義的方式顯示，所以我也修改了腳本以強制代碼使用實際值，而不是al [j]和para [我]顯示。

Names Default To Here( 1 );

sourcedt = Open( "$SAMPLE_DATA\Airline Delays.jmp" );

dt = sourcedt << Stack(
 columns( :Elapsed Time, :Arrival Delay, :Distance ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Value" )
);

Summarize( dt, al = By( :Airline ) );
Summarize( dt, mon = By( :Month ) );
Summarize( dt, para = By( :Label ) );
alWindowList = {};

For( j = 1, j <= N Items( al ), j++,
 nw = New Window( al[j],
  V List Box(
 
   For( i = 1, i <= N Items( para ), i++,
    Eval(
     Substitute(
       Expr(
        Graph Builder(
         Size( 230, 300 ),
         Fit to Window( "Off" ),
         Show Control Panel( 0 ),
         Variables( X( :Month ), Y( :Value ), Overlay( :Day of Week ) ),
         Elements( Points( X, Y, Legend( 1 ) ) ),
         Where( :Airline == __al__ & :Label == __para__ ),
         SendToReport(
          Dispatch( {}, "Value", ScaleBox, {Min( -10 ), Minor Ticks( 0 )} ),
          Dispatch( {}, "graph title", TextEditBox, {Set Text( "" )} ),
          Dispatch( {}, "Y title", TextEditBox, {Set Text( para[i] )} )
         )
        ) << report
       ),
      Expr( __al__ ), al[j],
      Expr( __para__ ), para[i]
     )
    )
   )
  )
 );
 Insert Into( alWindowList, nw );
);

Re：通過循環組合圖形窗口

嗨txnelson，

 

我必須為不同的上下文重用這個（類似的）代碼，但它似乎不再起作用了。也就是說，窗口標題不會顯示在“組合窗口”列表中，也不會顯示為要添加到儀表板的可用報告。我重新運行下面的代碼，存在同樣的問題。我們最近升級到14.2 .....這可能是問題嗎？

 

非常感謝。

Derchieh