60425_fr-FR

liliconcom

Comment concaténer dynamiquement n tables de données dans JSL

Je crée un script pour automatiser le flux de travail pour un collègue qui est un utilisateur novice de JMP. La première opération du script consiste à combiner toutes les itérations de données des exécutions du modèle. Ceci est accompli par,

 

1. L'utilisateur est invité à sélectionner le répertoire des tables de données individuelles qui représentent n itérations d'un modèle exécuté.
2. Le script ouvre toutes les tables de données d'itération qui ont un nom prédéfini suivi du numéro d'itération : « SGR Scenaio Iteration i ».
3. Au fur et à mesure que chaque table de données d'itération est ouverte, une colonne Itération est ajoutée et préremplie avec le numéro d'itération.
4. Une fois que toutes les tables de données ont été ouvertes, les tables de données 2 à 10 sont concaténées à la première table de données, pour créer une nouvelle table de données combinée nommée "SGR Scenario Combined Iterations".
5. Les itérations d'origine sont alors fermées sans être sauvegardées ; ceci est intentionnel pour préserver les tables de données d'origine.

Voici le code de la première partie du script qui accomplit les tâches répertoriées ci-dessus :

 

Names Default to Here(1);
Delete Symbols();

//----------------------------------------------------------------------------------------------
// Select file path, then import and combine all iteration data tables into a single data table 
// of replicates of sorties completed across iterations.
//----------------------------------------------------------------------------------------------
path = Pick Directory("Select the directory containing the iteration files.");

iterationFile = path || "SGR Scenario Iteration 1.jmp";
dtIterationTables = Open(iterationFile, "Invisible");

// add Iteration column
dtIterationTables << New Column(
 "Iteration",
 Ordinal,
 Set Each Value(1)
);

dtIterationTables << Move Selected Columns(
 {"Iteration"},
 After(:Time of Day)
);

// get remaining iteration tables
i = 2;
iterationFile = path || "SGR Scenario Iteration 2.jmp";
While(File Exists(iterationFile),
 nTables = i;
 dtIterationFile = Open(iterationFile, "Invisible");
 
 // add Iteration column
 dtIterationFile << New Column(
  "Iteration",
  Ordinal,
  Set Each Value(i)
 );

 dtIterationFile << Move Selected Columns(
  {"Iteration"},
  After(:Time of Day)
 );
 
 //look for next iteration table
 i++;
 iterationFile = path || "SGR Scenario Iteration " || Char(i) || ".jmp";
);

// concatenate current interation table to first iteration table
// NOTE: AWAITING RESPONSE ON HOW TO MAKE THIS PROCESS DYNAMIC
Data Table("SGR Scenario Iteration 1") << Concatenate(
 Data Table("SGR Scenario Iteration 2"),
 Data Table("SGR Scenario Iteration 3"),
 Data Table("SGR Scenario Iteration 4"),
 Data Table("SGR Scenario Iteration 5"),
 Data Table("SGR Scenario Iteration 6"),
 Data Table("SGR Scenario Iteration 7"),
 Data Table("SGR Scenario Iteration 8"),
 Data Table("SGR Scenario Iteration 9"),
 Data Table("SGR Scenario Iteration 10"),
 Output Table("SGR Scenario Combined Iterations")
);

// close original iteration tables
i = 1;
While(i <= nTables,
 dtIterationTable = Data Table("SGR Scenario Iteration " || Char(i));
 Close(dtIterationTable);
 Clear Symbols(dtIterationTable);
 i++;
);<BR />

Le problème que j'ai est avec l'étape 4. Le script actuel est codé en dur pour concaténer 10 tables de données, mais je dois pouvoir concaténer n tables de données afin que mon collègue ne soit pas obligé de ne traiter que 10 itérations, ou pire, d'avoir à essayer de modifier le code JSL à chaque fois que la taille de l'ensemble de données change (lire : vient à moi de changer le script). Vous pouvez voir dans le code que j'ai une variable, nTables , c'est-à-dire le nombre de tables de données ouvertes, car tous les autres blocs de code sont configurés pour gérer n tableaux de données.

 

Toute aide à ce sujet serait grandement appréciée.

Fusion et nettoyage des donnéesRe : Comment concaténer dynamiquement n tables de données dans JSL

J'ai dû faire un peu de nettoyage sur votre solution suggérée, mais cela a essentiellement fonctionné. Voici le code mis à jour pour le front-end de mon script :

 

Names Default to Here(1);
Delete Symbols();

//----------------------------------------------------------------------------------------------
// Select file path, then import and combine all iteration data tables into a single data table 
// of replicates of sorties completed by te hour across iterations.
//----------------------------------------------------------------------------------------------
path = Pick Directory("Select the directory containing the iteration files.");

iterationFile = path || "SGR Scenario Iteration 1.jmp";
dtIterationTables = Open(iterationFile, "Invisible");
dtIterationTables << Set Name("SGR Scenario Combined Iterations");

// add Iteration column
dtIterationTables << New Column(
 "Iteration",
 Ordinal,
 Set Each Value(1)
);

dtIterationTables << Move Selected Columns(
 {"Iteration"},
 After(:Time of Day)
);

// get remaining iteration tables
i = 2;
iterationFile = path || "SGR Scenario Iteration " || Char(i) || ".jmp";
While(File Exists(iterationFile),
 dtIterationFile = Open(iterationFile, "Invisible");
 
 // add Iteration column
 dtIterationFile << New Column(
  "Iteration",
  Ordinal,
  Set Each Value(i)
 );
 
 // append current iteration table to combined table
 dtIterationTables = dtIterationTables << Concatenate(
  dtIterationFile,
  Append to first table(1)
 );
 Close(dtIterationFile, NoSave);
 
 //look for next iteration data table
 i++;
 iterationFile = path || "SGR Scenario Iteration " || Char(i) || ".jmp";
);

//----------------------------------------------------------------------------------------------
// Add Replicate column and then create data table with simplified statistical model.
//----------------------------------------------------------------------------------------------
dtIterationTables << New Column(
 "Replicate",
 Ordinal,
 Formula(Num(Right(:Time of Day, Length(:Time of Day) - Contains(:Time of Day, " "))))
);

dtIterationTables << Move Selected Columns(
 {"Replicate"},
 After(:Iteration)
);

// make data set more flexible by stacking the hour columns to simplify the statistical model
dtIterationTables << Stack(
 columns(
  :Name("1200"),
  :Name("1300"),
  :Name("1400"),
  :Name("1500"),
  :Name("1600"),
  :Name("1700"),
  :Name("1800"),
  :Name("1900"),
  :Name("2000"),
  :Name("2100"),
  :Name("2200")
 ),
 Source Label Column("Hour"),
 Stacked Data Column("Sorties Completed"),
 Copy formula(0),
 Name("Non-stacked columns")(Keep(:Iteration, :Replicate)),
 Output Table("Combined SGR Scenario Iterations")
);

dtAllIterations = Data Table("Combined SGR Scenario Iterations");
Close(dtIterationTables, NoSave);

dtAllIterations:Hour << Set Modeling Type("Ordinal");
dtAllIterations << Save As(path || "Combined SGR Scenario Iterations.jmp");

Merci pour l'aide!

Re : Comment concaténer dynamiquement n tables de données dans JSL

Jetez un oeil au code ci-dessous.Je devrais te donner ce que tu veux.Je n'ai pas vraiment pu tester le code, mais je crois qu'il est assez précis.Il adopte l'approche de ne pas avoir à garder une trace du nombre de tables de données qui ont été lues, car il effectue la concaténation après l'entrée de chaque fichier.

Names Default to Here(1);
Delete Symbols();

//----------------------------------------------------------------------------------------------
// Select file path, then import and combine all iteration data tables into a single data table 
// of replicates of sorties completed across iterations.
//----------------------------------------------------------------------------------------------
path = Pick Directory("Select the directory containing the iteration files.");

iterationFile = path || "SGR Scenario Iteration 1.jmp";
dtBaseIterationTables = Open(iterationFile, "Invisible");

dtBaseIterationTable << set name( "SGR Scenario Combined Iterations" );

// add Iteration column
dtBaseIterationTables << New Column(
 "Iteration",
 Ordinal,
 Set Each Value(1)
);

dtBaseIterationTables << Move Selected Columns(
 {"Iteration"},
 After(:Time of Day)
);

// get remaining iteration tables
i = 2;
//iterationFile = path || "SGR Scenario Iteration 2.jmp";
While(File Exists(path || "SGR Scenario Iteration " || char( i ) || ".jmp";),
 //nTables = i;
 dtIterationFile = Open(path || "SGR Scenario Iteration " || char( i ) || ".jmp", "Invisible");
 
 // add Iteration column
 dtIterationFile << New Column(
  "Iteration",
  Ordinal,
  Set Each Value(i)
 );

 /* // Not required since the columns from this table will align with the base table
 dtIterationFile << Move Selected Columns(
  {"Iteration"},
  After(:Time of Day)
 )*/;
 
 //look for next iteration table
 i++;
 // iterationFile = path || "SGR Scenario Iteration " || Char(i) || ".jmp"; 
 
 dtBaseIterationTables = dtBaseIterationTables << Concatenate( dtIterationFile, append to first table( 1 ) );
 
 close( dtIterationFile, nosave );
);<BR /><BR />dtBaseIterationTables << Show Window( 1 );

/*// concatenate current interation table to first iteration table
// NOTE: AWAITING RESPONSE ON HOW TO MAKE THIS PROCESS DYNAMIC
Data Table("SGR Scenario Iteration 1") << Concatenate(
 Data Table("SGR Scenario Iteration 2"),
 Data Table("SGR Scenario Iteration 3"),
 Data Table("SGR Scenario Iteration 4"),
 Data Table("SGR Scenario Iteration 5"),
 Data Table("SGR Scenario Iteration 6"),
 Data Table("SGR Scenario Iteration 7"),
 Data Table("SGR Scenario Iteration 8"),
 Data Table("SGR Scenario Iteration 9"),
 Data Table("SGR Scenario Iteration 10"),
 Output Table("SGR Scenario Combined Iterations")
);

// close original iteration tables
i = 1;
While(i <= nTables,
 dtIterationTable = Data Table("SGR Scenario Iteration " || Char(i));
 Close(dtIterationTable);
 Clear Symbols(dtIterationTable);
 i++;
);*/