親愛なるみんな、
グラフ ビルダーで作成したものを並べ替えて、グラフのレイアウトを改善する方法を探しています。 「ページ」オプションを使用して、9 つの小さなグラフを下に配置しました。 私が望むのは、それらを 3X3 に配置することです。これは、見栄えがよくなるためです (ある種のトレリス表示)。 「ラップ」ボタンを使用してこれを取得できることは知っていますが、その場合、すべての軸が等しく設定されます。「ページ」に使用するグループ化変数は、非常に異なる単位と非常に異なる順序のパラメーターに関連しているため、これはオプションではありません大きさの…。 同様に、「Xグループ」または「Yグループ」も機能しません。 グラフをジャーナルに送信して手動で並べ替えようとしましたが、グラフを別のグラフの隣にうまく貼り付けることができません。
レポートが「picture/displayboxes」などを使用して構造化されていることを確認するために、このためのスクリプトを作成する必要があるかどうかはわかりませんが、問題は、グラフビルダーのスクリプトを保存して後で再実行するたびに、グラフは表示されていません。軸のみが… 最も簡単な方法は (私が思うに)、最初にグラフ ビルダーでグラフを作成し、それをジャーナルに送信してから、ジャーナルを再配置することです。 右？
これに対処する方法についてのアイデアはありますか？
どうもありがとう！！
ヤンネ
個々のグラフを作成してから、それらをウィンドウにまとめることができます。常に同じ 9 つのグラフを表示する場合は、以下のスクリプトで十分かもしれません。レベルが変更された場合、ループでウィンドウ階層を構築できます。
Names default to here( 1 );
//Open sample data and create a binning column
dt = Open("$SAMPLE_DATA/Body Fat.jmp");
dt << New Column( "Age (decades)",
Numeric,
Nominal,
Format( "Best", 10 ),
Formula( 10 * Floor( :Name( "Age (years)" ) / 10 ) )
);
//function to build each individual graph with a local data filter
GraphDecade = function({decade},
gb = dt << Graph Builder(
Size( 300, 300 ),
Show Control Panel( 0 ),
Show Legend( 0 ),
Variables( X( :Name( "Age (years)" ) ) ),
Elements( Histogram( X, Legend( 5 ) ) ),
SendToReport( Dispatch( {},
"Graph Builder",
OutlineBox,
{Set Title( "Decade: " || Char( decade ) )} )
),
Local Data Filter(
Close Outline( 1 ),
Add Filter(
columns( :Name( "Age (decades)" ) ),
Where( :Name( "Age (decades)" ) == decade ),
Display( :Name( "Age (decades)" ), Size( 256, 168 ), List Display )
)
)
)
);
//Window with graphs
win = new window( "Ages by Decade",
V List Box(
Text Box( "Distribution of Ages within Decades", << Set Font Size( 20 ), << Set Width( 600 ) ),
H List Box(
vb1 = V List Box(
GraphDecade(20),
GraphDecade(40)
),
vb2 = V List Box(
GraphDecade(30),
GraphDecade(50)
)
)
)
);
(vb1[1] << Find("Local Data Filter")) << visibility("collapse");
(vb1[2] << Find("Local Data Filter")) << visibility("collapse");
(vb2[1] << Find("Local Data Filter")) << visibility("collapse");
(vb2[2] << Find("Local Data Filter")) << visibility("collapse");
編集：バグ修正
