37970_es-ES

liliconcom

Cómo trazar datos de dos tablas sin combinar las tablas

Hola Mundo,

 

Hacemos mediciones en nuestro laboratorio y siempre terminamos con múltiples tablas de datos que contienen datos medidos y datos filtrados. Por algunas razones prácticas, no queremos combinar las tablas para trazar los datos medidos y los datos filtrados. ¿Es posible trazar los datos xy de una tabla y los datos xy de la otra tabla en el mismo eje en un diagrama de dispersión tipo "Ajustar y por x" (tipo de gráfico jmp)?

 

Estoy buscando la misma flexibilidad que ofrece Matlab con la función de trazado.

 

Se agradecen las secuencias de comandos o las explicaciones sobre cómo lograr esto con la interfaz gráfica de usuario de JMP.

 

 

Re: Cómo trazar datos de dos tablas sin combinarlas

Me gusta usar los configuradores xaxis() o yaxis() para pasar el script del eje a un gráfico. El video muestra cómo recortar el guión para omitir los bits predeterminados para que no parezca tan complicado. Agregar líneas de referencia a gráficos muestra los configuradores de los ejes x e y con una plataforma.También Éste .

Re: Cómo trazar datos de dos tablas sin combinarlas

Hola Craige@ Craige_Hales

 

En este ejemplo, si queremos agregar la cuadrícula mayor y la cuadrícula menor, ¿cómo podemos hacerlo en el script? Parece que este nuevo gráfico de ventana no puede generar el script. Se adjunta una imagen para mostrar mi pregunta. Mi gráfico no tiene el botón del triángulo rojo como en el suyo.

 

Re: Cómo trazar datos de dos tablas sin combinarlas

Gracias por su respuesta Craige_Hales ,

 

Como ya señaló, no es posible utilizar la increíble característica de hacer selecciones en los gráficos y ver directamente las relaciones correspondientes en otros gráficos. Empiezo a creer que no hay una solución fácil excepto cambiar el nombre de las columnas y fusionar las tablas para obtener los datos con todas las características en un solo gráfico.

 

Esperemos que haya una solución fácil en una versión futura de jmp

 

Re: Cómo trazar datos de dos tablas sin combinarlas

Puedes hacer tus propios gráficos con JSL como este. Al seleccionar puntos en los gráficos, no se seleccionarán filas en las tablas porque se utilizan copias de los datos. Si necesita una leyenda, también tendrá que crearla, tal vez usando texto(...) como se muestra. Te faltarán algunas otras características proporcionadas por diferentes plataformas (splines, ajustes) que pueden hacer que otras ideas que combinan temporalmente las tablas se vean mucho mejor.

ab = New Table( "ab data",
    Add Rows( 4 ),
    New Column( "a", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [11, 12, 15, 17, 19] ) ),
    New Column( "b", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [30, 40, 20, 70, 50] ) )
);

cd = New Table( "cd data",
    Add Rows( 4 ),
    New Column( "c", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [21, 22, 25, 27] ) ),
    New Column( "d", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [10, 20, 30, 60] ) )
);

New Window( "Example",
    Graph Box(
        Y Scale( 0, 80 ),
        X Scale( 10, 30 ),
        FrameSize(500,200),
        Title( "ab and cd" ),
        // comma delimited parameters above, semicolon delimited statements below
        Pen Color( "red" );
        Text Color( "red" );
        Pen Size( 4 );
        Marker Size( 6 );
        Marker( ab:a[1 :: N Rows( ab )], ab:b[1 :: N Rows( ab )] );
        Line( ab:a[1 :: N Rows( ab )], ab:b[1 :: N Rows( ab )] );
        Text( {ab:a[N Rows( ab )], ab:b[N Rows( ab )]}, " ab" );
        Pen Color( "green" );
        Text Color( "green" );
        Pen Size( 2 );
        Marker Size( 3 );
        Marker( cd:c[1 :: N Rows( cd )], cd:d[1 :: N Rows( cd )] );
        Line( cd:c[1 :: N Rows( cd )], cd:d[1 :: N Rows( cd )] );
        Text( {cd:c[N Rows( cd )], cd:d[N Rows( cd )]}, " cd" );
    )
);

(Hay muchas repeticiones en este ejemplo; es más simple de lo que parece).

Thick red curve and thin green curve from different tablesThick red curve and thin green curve from different tablesCurva roja gruesa y curva verde delgada de diferentes tablas

Re: Cómo trazar datos de dos tablas sin combinarlas

Jim, gracias por la solución propuesta. Esto solo funciona cuando las dos columnas de ambas tablas tienen el mismo nombre. En realidad estoy buscando una solución donde este no sea el caso. Puedo oírte preguntar por qué no cambiar los nombres de las columnas Trabajo con muchos conjuntos de datos que contienen, en muchos casos, diferentes nombres de columnas por proyecto. I que habrá una función de trazado jmp en el futuro que permitirá elegir múltiples columnas xey de múltiples tablas de datos.

 

 

Re: Cómo trazar datos de dos tablas sin combinarlas

Algo como esto podría funcionar. El siguiente ejemplo tiene 2 tablas de datos, una con datos válidos y otra con valores atípicos. Luego, para utilizar los 2 juntos, se crea una nueva tabla de datos "privada" y el gráfico se ejecuta desde ella.

Names Default To Here( 1 );

// Create the data table with the good data
New Table( "Big Class",
 Add Rows( 36 ),
 New Column( "name",
  Character,
  "Nominal",
  Set Values(
   {"KATIE", "LOUISE", "JANE", "JACLYN", "LILLIE", "TIM", "JAMES", "BARBARA", "ALICE",
   "SUSAN", "JOHN", "JOE", "MICHAEL", "DAVID", "LESLIE", "CAROL", "PATTY", "FREDERICK",
   "HENRY", "LEWIS", "EDWARD", "CHRIS", "JEFFREY", "MARY", "AMY", "ROBERT", "WILLIAM",
   "CLAY", "MARK", "DANNY", "MARTHA", "MARION", "PHILLIP", "LINDA", "KIRK", "LAWRENCE"}
  )
 ),
 New Column( "age",
  Numeric,
  "Ordinal",
  Set Values(
   [12, 12, 12, 12, 12, 12, 12, 13, 13, 13, 13, 13, 13, 13, 14, 14, 14, 14, 14, 14, 14,
   14, 14, 15, 15, 15, 15, 15, 15, 15, 16, 16, 16, 17, 17, 17]
  )
 ),
 New Column( "sex",
  Character( 1 ),
  "Nominal",
  Set Values(
   {"F", "F", "F", "F", "F", "M", "M", "F", "F", "F", "M", "M", "M", "M", "F", "F", "F",
   "M", "M", "M", "M", "M", "M", "F", "F", "M", "M", "M", "M", "M", "F", "F", "M", "F",
   "M", "M"}
  )
 ),
 New Column( "height",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 5, 0 ),
  Set Values(
   [59, 61, 55, 66, 52, 60, 61, 60, 61, 56, 65, 63, 58, 59, 65, 63, 62, 63, 65, 64, 68,
   64, 69, 62, 64, 67, 65, 66, 62, 66, 65, 60, 68, 62, 68, 70]
  )
 ),
 New Column( "weight",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 5, 0 ),
  Set Values(
   [95, 123, 74, 145, 64, 84, 128, 112, 107, 67, 98, 105, 95, 79, 142, 84, 85, 93, 119,
   92, 112, 99, 113, 92, 112, 128, 111, 105, 104, 106, 112, 115, 128, 116, 134, 172]
  )
 ),
 New Column( "source",
  Character,
  "Nominal",
  Set Values(
   {"Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid",
   "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid",
   "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid",
   "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid"}
  )
 )
);

// Create the outlier data table
New Table( "Outliers",
 Add Rows( 4 ),
 New Column( "name",
  Character,
  "Nominal",
  Set Values( {"ROBERT", "JUDY", "ELIZABETH", "ALFRED"} )
 ),
 New Column( "age",
  Numeric,
  "Ordinal",
  Format( "Fixed Dec", 5, 0 ),
  Set Values( [12, 14, 14, 14] )
 ),
 New Column( "sex", Character( 1 ), "Nominal", Set Values( {"M", "F", "F", "M"} ) ),
 New Column( "height",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 5, 0 ),
  Set Values( [51, 61, 62, 64] )
 ),
 New Column( "weight",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 5, 0 ),
  Set Values( [79, 81, 91, 99] )
 ),
 New Column( "source",
  Character,
  "Nominal",
  Set Values( {"Outlier", "Outlier", "Outlier", "Outlier"} )
 )
);

// Display chart by creating a nondisplayed data table
p1 = Data Table( "Big Class" ) << Concatenate( Data Table( "Outliers" ), private );
p1 << color by column( :source );
p1 << Bivariate( Y( :height ), X( :weight ), Fit Line( {Line Color( {213, 72, 87} )} ) );

Re: Cómo trazar datos de dos tablas sin combinarlas

Gracias por la reacción,

 

lamentablemente esto no es lo que busco, en mis mediciones no siempre hay relación con los datos filtrados. Algunos valores se excluyen y se consideran valores atípicos. Pero todavía me gustaría trazarlos y ser consciente de los valores atípicos.

Re: Cómo trazar datos de dos tablas sin combinarlas

¿Quizás esto es lo que necesitas?

 

http://www.jmp.com/support/help/13/Virtually_Join_Data_Tables.shtml