37970_de-DE

liliconcom

So zeichnen Sie Daten aus zwei Tabellen auf, ohne die Tabellen zu kombinieren

Hallo Welt,

 

Wir führen Messungen in unserem Labor durch und erhalten am Ende immer mehrere Datentabellen, die gemessene Daten und gefilterte Daten enthalten. Aus praktischen Gründen möchten wir die Tabellen nicht kombinieren, um die gemessenen Daten und gefilterten Daten darzustellen. Ist es möglich, die xy-Daten aus einer Tabelle und die xy-Daten aus der anderen Tabelle auf derselben Achse in einem Streudiagramm wie „Y nach x anpassen“ (jmp-Diagrammtyp) darzustellen?

 

Ich suche die gleiche Flexibilität, die Matlab mit der Plot-Funktion bietet.

 

Wir freuen uns über Skripts oder Erklärungen, wie dies mit der JMP-GUI durchgeführt werden kann.

 

 

Betreff: So zeichnen Sie Daten aus zwei Tabellen auf, ohne die Tabellen zu kombinieren

Ich verwende gerne die Setter xaxis() oder yaxis(), um das Achsenskript an ein Diagramm zu übergeben. Das Video zeigt, wie das Skript so gekürzt wird, dass die Standardbits weggelassen werden, damit es nicht so kompliziert aussieht. Fügen Sie Ref-Linien zu Diagrammen hinzu zeigt die X-Achsen- und Y-Achsen-Einsteller mit einer Plattform.Auch Dieses hier .

Betreff: So zeichnen Sie Daten aus zwei Tabellen auf, ohne die Tabellen zu kombinieren

Craige_Hales

 

Wenn wir in diesem Beispiel das Hauptraster und das Nebenraster hinzufügen möchten, wie können wir das im Skript tun? Es scheint, dass dieses neue Fensterdiagramm das Skript nicht ausgeben kann. Ein Bild ist beigefügt, um meine Frage zu zeigen. Mein Plot verfügt nicht über die rote Dreiecksschaltfläche wie in Ihrem Plot.

 

Betreff: So zeichnen Sie Daten aus zwei Tabellen auf, ohne die Tabellen zu kombinieren

Vielen Dank für Ihre Antwort Craige_Hales ,

 

Wie Sie bereits betont haben, ist es nicht möglich, die tolle Funktion, in den Diagrammen Auswahlen zu treffen, zu nutzen und die entsprechenden Beziehungen in anderen Diagrammen direkt zu sehen. Ich fange an zu glauben, dass es keine einfache Lösung gibt, außer die Spalten umzubenennen und die Tabellen zusammenzuführen, um die Daten mit allen Funktionen in einem einzigen Diagramm zu erhalten.

 

Hoffentlich wird es in einer zukünftigen Version von jmp eine einfache Lösung geben

 

Betreff: So zeichnen Sie Daten aus zwei Tabellen auf, ohne die Tabellen zu kombinieren

So können Sie mit JSL Ihre eigenen Diagramme erstellen. Durch die Auswahl von Punkten in den Diagrammen werden keine Zeilen in den Tabellen ausgewählt, da Kopien der Daten verwendet werden. Wenn Sie eine Legende benötigen, müssen Sie diese ebenfalls erstellen, möglicherweise mit text(...) wie gezeigt. Ihnen werden einige andere Funktionen fehlen, die von verschiedenen Plattformen bereitgestellt werden (Splines, Passungen), wodurch andere Ideen, die die Tabellen vorübergehend kombinieren, möglicherweise viel besser aussehen.

ab = New Table( "ab data",
    Add Rows( 4 ),
    New Column( "a", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [11, 12, 15, 17, 19] ) ),
    New Column( "b", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [30, 40, 20, 70, 50] ) )
);

cd = New Table( "cd data",
    Add Rows( 4 ),
    New Column( "c", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [21, 22, 25, 27] ) ),
    New Column( "d", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [10, 20, 30, 60] ) )
);

New Window( "Example",
    Graph Box(
        Y Scale( 0, 80 ),
        X Scale( 10, 30 ),
        FrameSize(500,200),
        Title( "ab and cd" ),
        // comma delimited parameters above, semicolon delimited statements below
        Pen Color( "red" );
        Text Color( "red" );
        Pen Size( 4 );
        Marker Size( 6 );
        Marker( ab:a[1 :: N Rows( ab )], ab:b[1 :: N Rows( ab )] );
        Line( ab:a[1 :: N Rows( ab )], ab:b[1 :: N Rows( ab )] );
        Text( {ab:a[N Rows( ab )], ab:b[N Rows( ab )]}, " ab" );
        Pen Color( "green" );
        Text Color( "green" );
        Pen Size( 2 );
        Marker Size( 3 );
        Marker( cd:c[1 :: N Rows( cd )], cd:d[1 :: N Rows( cd )] );
        Line( cd:c[1 :: N Rows( cd )], cd:d[1 :: N Rows( cd )] );
        Text( {cd:c[N Rows( cd )], cd:d[N Rows( cd )]}, " cd" );
    )
);

(In diesem Beispiel gibt es viele Wiederholungen; es ist einfacher als es aussieht.)

Thick red curve and thin green curve from different tablesThick red curve and thin green curve from different tablesDicke rote Kurve und dünne grüne Kurve aus verschiedenen Tabellen

Betreff: So zeichnen Sie Daten aus zwei Tabellen auf, ohne die Tabellen zu kombinieren

Jim, vielen Dank für die vorgeschlagene Lösung. Dies funktioniert nur, wenn die beiden Spalten in beiden Tabellen denselben Namen haben. Eigentlich suche ich nach einer Lösung, bei der dies nicht der Fall ist. Ich kann hören, wie Sie fragen, warum Sie nicht die Spaltennamen ändern Ich arbeite mit vielen Datensätzen, die in vielen Fällen unterschiedliche Spaltennamen pro Projekt enthalten. Ich weiß, dass es in Zukunft eine JMP-Plotfunktion geben wird, die es ermöglicht, mehrere x- und y-Spalten aus mehreren Datentabellen auszuwählen.

 

 

Betreff: So zeichnen Sie Daten aus zwei Tabellen auf, ohne die Tabellen zu kombinieren

So etwas könnte funktionieren. Das folgende Beispiel enthält zwei Datentabellen, eine mit gültigen Daten und eine mit Ausreißern. Um die beiden dann zusammen zu verwenden, wird eine neue, „private“ Datentabelle erstellt und das Diagramm darauf ausgeführt.

Names Default To Here( 1 );

// Create the data table with the good data
New Table( "Big Class",
 Add Rows( 36 ),
 New Column( "name",
  Character,
  "Nominal",
  Set Values(
   {"KATIE", "LOUISE", "JANE", "JACLYN", "LILLIE", "TIM", "JAMES", "BARBARA", "ALICE",
   "SUSAN", "JOHN", "JOE", "MICHAEL", "DAVID", "LESLIE", "CAROL", "PATTY", "FREDERICK",
   "HENRY", "LEWIS", "EDWARD", "CHRIS", "JEFFREY", "MARY", "AMY", "ROBERT", "WILLIAM",
   "CLAY", "MARK", "DANNY", "MARTHA", "MARION", "PHILLIP", "LINDA", "KIRK", "LAWRENCE"}
  )
 ),
 New Column( "age",
  Numeric,
  "Ordinal",
  Set Values(
   [12, 12, 12, 12, 12, 12, 12, 13, 13, 13, 13, 13, 13, 13, 14, 14, 14, 14, 14, 14, 14,
   14, 14, 15, 15, 15, 15, 15, 15, 15, 16, 16, 16, 17, 17, 17]
  )
 ),
 New Column( "sex",
  Character( 1 ),
  "Nominal",
  Set Values(
   {"F", "F", "F", "F", "F", "M", "M", "F", "F", "F", "M", "M", "M", "M", "F", "F", "F",
   "M", "M", "M", "M", "M", "M", "F", "F", "M", "M", "M", "M", "M", "F", "F", "M", "F",
   "M", "M"}
  )
 ),
 New Column( "height",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 5, 0 ),
  Set Values(
   [59, 61, 55, 66, 52, 60, 61, 60, 61, 56, 65, 63, 58, 59, 65, 63, 62, 63, 65, 64, 68,
   64, 69, 62, 64, 67, 65, 66, 62, 66, 65, 60, 68, 62, 68, 70]
  )
 ),
 New Column( "weight",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 5, 0 ),
  Set Values(
   [95, 123, 74, 145, 64, 84, 128, 112, 107, 67, 98, 105, 95, 79, 142, 84, 85, 93, 119,
   92, 112, 99, 113, 92, 112, 128, 111, 105, 104, 106, 112, 115, 128, 116, 134, 172]
  )
 ),
 New Column( "source",
  Character,
  "Nominal",
  Set Values(
   {"Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid",
   "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid",
   "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid",
   "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid", "Valid"}
  )
 )
);

// Create the outlier data table
New Table( "Outliers",
 Add Rows( 4 ),
 New Column( "name",
  Character,
  "Nominal",
  Set Values( {"ROBERT", "JUDY", "ELIZABETH", "ALFRED"} )
 ),
 New Column( "age",
  Numeric,
  "Ordinal",
  Format( "Fixed Dec", 5, 0 ),
  Set Values( [12, 14, 14, 14] )
 ),
 New Column( "sex", Character( 1 ), "Nominal", Set Values( {"M", "F", "F", "M"} ) ),
 New Column( "height",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 5, 0 ),
  Set Values( [51, 61, 62, 64] )
 ),
 New Column( "weight",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 5, 0 ),
  Set Values( [79, 81, 91, 99] )
 ),
 New Column( "source",
  Character,
  "Nominal",
  Set Values( {"Outlier", "Outlier", "Outlier", "Outlier"} )
 )
);

// Display chart by creating a nondisplayed data table
p1 = Data Table( "Big Class" ) << Concatenate( Data Table( "Outliers" ), private );
p1 << color by column( :source );
p1 << Bivariate( Y( :height ), X( :weight ), Fit Line( {Line Color( {213, 72, 87} )} ) );

Betreff: So zeichnen Sie Daten aus zwei Tabellen auf, ohne die Tabellen zu kombinieren

Vielen Dank für die Reaktion,

 

Leider ist das nicht das, wonach ich suche, bei meinen Messungen besteht nicht immer ein Zusammenhang mit den gefilterten Daten. Einige Werte werden ausgeschlossen und als Ausreißer betrachtet. Aber ich würde sie trotzdem gerne grafisch darstellen und mir der Ausreißer bewusst sein.

Betreff: So zeichnen Sie Daten aus zwei Tabellen auf, ohne die Tabellen zu kombinieren

Vielleicht ist es das, was Sie brauchen?

 

http://www.jmp.com/support/help/13/Virtually_Join_Data_Tables.shtml