How to show on graph only failed T test

Adir52

Hi all,

i am using the following script in order to perform T test for between two groups (stressed abd control). 

	Oneway(
				Y( :Shift ),
				X( :Group ),
				by(:Test),
				t Test( 1 ),
				Box Plots( 1 ),
				X Axis Proportional( 0 ),
				Points Jittered( 1 ),
				Grand Mean( 0 ),
				SendToReport(
				Dispatch(
				{},
				"Oneway Plot",
				FrameBox,
				{DispatchSeg(
				Box Plot Seg( 1 ),
				{Box Type( "Outlier" ), Line Color( "Red" )}
				), DispatchSeg(
				Box Plot Seg( 2 ),
				{Box Type( "Outlier" ), Line Color( "Red" )}
				)}
				)
				)
			);

  as you can see i am performing the T test for each "Test" and i have Thousands  of tests. my question if there is a option to show on the graph only the test where the T test got failed? 

 

Thanks!!

txnelson

There are multiple ways to solve this question in JMP.  I prefer to use Response Screening to do a very fast run through of the data to get just the p-values of the analyses, and then take those results and select the desired data for analysis.  Below is a simple script that does that on some sample data I create to match your specific data table column names.

names default to here(1);

// Modify a sample data table to mimic your t-test code
dtSemi = open("$SAMPLE_DATA/semiconductor capability.jmp", invisible);

dtSemi << select where( :Site > 2 );
dtSemi << delete rows;
dtSemi:Site << set name( "Group" );
colNames = dtSemi << get column names( continuous );

dt = dtSemi << stack( columns(colNames) ,
	Source Label Column( "Test" ),
	Stacked Data Column( "Shift" ),
	Name( "Non-stacked columns" )(Keep( :Group ))
);

close( dtSemi, nosave );

// The above code just creates a sample data table....The code below generates
// the desired output

// Now run the Response Screening to get the failed t-tests
rs = dt << Response Screening( Y( :Shift ), X( :Group ), Grouping( :Test ) );
dtRS = rs << Get PValues;
//dtRS << show window( 0 );
report(rs) << close window;

// select all of the failed t-tests and get their test names
// We are using failue of .1 as the target.....just change the
// target value if you want .05 or something else as the failure value
dtRS << select where( :PValue <= .1 );

If( N Rows(dtRS << get selected rows ) > 0,
	dtRS << delete rows;
);

failingTests = dtRS:Test << get values;

// close the dtRS data table that is no longer needed
close( dtRS, nosave );

// Now select the Tests in the original data table that are not significant
dt << select where( contains( failingTests, :Test ) );

If( N Rows( dt << get selected rows ) > 0,
	dt << invert row selection;
	dt << hide and exclude ;
	dt << clear select;
);

// Run your code
Oneway(
				Y( :Shift ),
				X( :Group ),
				by(:Test),
				t Test( 1 ),
				Box Plots( 1 ),
				X Axis Proportional( 0 ),
				Points Jittered( 1 ),
				Grand Mean( 0 ),
				SendToReport(
				Dispatch(
				{},
				"Oneway Plot",
				FrameBox,
				{DispatchSeg(
				Box Plot Seg( 1 ),
				{Box Type( "Outlier" ), Line Color( "Red" )}
				), DispatchSeg(
				Box Plot Seg( 2 ),
				{Box Type( "Outlier" ), Line Color( "Red" )}
				)}
				)
				)
			);